How can I plot a Möbius strip? I tried this one, but I can't get it to work:
ParametricPlot3D[{
(5 + s*Cos[u/2]) Cos[u],
(5 + s*Cos[u/2]) Sin[u],
(s*Sin[u/2])}, {u, -20, 20}, {s, 0, 2 π}]
$\begingroup$
$\endgroup$
7
-
1$\begingroup$ Please post the code that you used that didn't work for you. Without the code, it's impossible for us to tell you what you did wrong. $\endgroup$– C. E.Sep 18, 2015 at 10:37
-
$\begingroup$ ParametricPlot3D [[[5 + sCos[u/2]]*Cos[u], [5 + sCos[u/2]]*Sin[u], s*Sin[u/2]], {u, -20, 20}, {s, 0 , 2 [Pi]}] @Pickett $\endgroup$– Priyadarshi PaulSep 18, 2015 at 10:41
-
1$\begingroup$ You need at least a space or a * between s and Cos and Sin. There are two instances where you forgot that. $\endgroup$– Sjoerd C. de VriesSep 18, 2015 at 10:49
-
2$\begingroup$ Just for fun: Here's an animation I made last year. $\endgroup$– Sjoerd C. de VriesSep 18, 2015 at 18:05
-
$\begingroup$ See also the attempted solution in the question Cutting bagels into linked halves. $\endgroup$– JensSep 18, 2015 at 20:16
|
Show 2 more comments
3 Answers
$\begingroup$
$\endgroup$
Equation taken form the wiki page
x[u_, v_] := (1 + (v/2) Cos[u/2]) Cos[u]
y[u_, v_] := (1 + (v/2) Cos[u/2]) Sin[u]
z[u_, v_] := (v/2) Sin[u/2]
plot = ParametricPlot3D[{x[u, v], y[u, v], z[u, v]}, {u, 0,
2 Pi}, {v, -1, 1}, Boxed -> False, Axes -> False]
$\begingroup$
$\endgroup$
1
Just for fun (using the parametrization from OP hyperlink):
mobius[r_, s_,t_] := {r + s Cos[t/2], r + s Cos[t/2], s Sin[t/2]} {Cos[t], Sin[t],
1}
Manipulate[
With[{wd = w},
Row[{
ParametricPlot[{u, v}, {u, -wd, wd}, {v, 0, 2 Pi},
AspectRatio -> 1/2, Epilog -> {Red, PointSize[0.04], Point@p},
ImageSize -> 200],
Show[ParametricPlot3D[mobius[r, u, v], {u, -wd, wd}, {v, 0, 2 Pi},
Mesh -> False, PlotStyle -> Yellow,
PerformanceGoal -> "Quality"],
Graphics3D[{Red, PointSize[0.04], Point[mobius[r, ##] & @@ p]}],
ImageSize -> 200]
}]], {r, 1, 2}, {w, 0.5, 2}, {{p, {0, 0}}, {{-w, 0}, {w, 2 Pi}},
Slider2D}]
-
$\begingroup$ computerbasedmath.org, animating math to make it more intuitive. $\endgroup$ Sep 18, 2015 at 17:42
$\begingroup$
$\endgroup$
...and, just for the sake of variation, here is a "minimal" Möbius strip (that is, a minimal surface with the topology of a Möbius strip). This example is due to Meeks.
ParametricPlot3D[{(r^3 - 1/r^3) Cos[3 θ]/3 + (r^2 + 1/r^2) Cos[2 θ] + (r - 1/r) Cos[θ],
(r^3 - 1/r^3) Sin[3 θ]/3 + (r^2 + 1/r^2) Sin[2 θ] + (r - 1/r) Sin[θ],
2 (r - 1/r) Sin[θ]}, {r, 1, 4/3}, {θ, -π, π}]
answered Oct 8, 2015 at 6:44