DSolve[ y''[x] + (a - (b x^2 - c) x^2) y[x] == 0, y[x], x]

I couldn't solve this equation, please help

  • 1
    $\begingroup$ There is no solution for the anharmonic oscillator in terms of the elementary or any standard special function as far as I know. $\endgroup$ – Nikolay Gromov Sep 17 '15 at 12:13
  • 1
    $\begingroup$ I get a solution in terms of DifferentialRoot. What version are using? $\endgroup$ – Michael E2 Sep 17 '15 at 13:31
  • $\begingroup$ You should mention what is your motivation to find a solution. The solution space is five-dimentional (two numbers form initial/boundary conditions and three constants) and so it not a well posed question even though one can find an exact general solution. $\endgroup$ – Artes Aug 31 at 23:02

Since the 12.1 version of Mathematica we can solve exactly this differential equation explicitly in a symbolic form involving tri-confluent Heun function.

solHT[x_] = DSolveValue[ y''[x] + (a - (b*x^2 - c)*x^2)*y[x] == 0, y[x], x]
(C[2] HeunT[-a - c^2/(4b), -2I Sqrt[-b], -I c/Sqrt[-b], 0, -2I Sqrt[-b], 
x])/E^(((I/6) x (3c - 2b x^2))/Sqrt[-b]) + 
E^(((I/6) x (3c - 2b x^2))/Sqrt[-b]) C[1]^2 HeunT[-a - c^2/(4b), 2I Sqrt[-b], 
I c/Sqrt[-b], 0, 2I Sqrt[-b], x] 
solHT[x] // TraditionalForm

enter image description here

The general solution involves three constants of the original differential equation $a, b$ and $c$ as well as two integration constants $c_1$ and $c_2$. We can also solve the equation prescribing symbolic constants and initial/boundary conditions, e.g.

With[{a = 3, b = 2, c = 1},
  TraditionalForm[ ds = DSolveValue[{y''[x] + (a - (b x^2 - c)x^2)y[x] == 0,
                                      y[1]==0,y'[0]==1}, y[x], x]//FullSimplify]]

enter image description here

Plot[ ds, {x, -2, 2}, PlotStyle -> Thick]

enter image description here

let's exploit another conditions:

With[{a = 1, b =-1/4, c = 1/2},
  TraditionalForm[ ds2 = DSolveValue[{y''[x] + (a - (b x^2 - c)x^2)y[x] == 0,
                                       y[0]==2,y'[0]==0}, y[x], x]//FullSimplify]]

enter image description here

Plot[ ds2, {x, -5, 5}, PlotStyle -> Thick, WorkingPrecision -> 30]

enter image description here

Exact symbolic solutions can be approximated with available analytic tools, e.g.

Series[ ds2, {x, 0, 14}]

enter image description here

| improve this answer | |

Mathematica can't solve analytically,but numerical yes can.

a = 3;
b = 2;
c = 1;
eq = {y''[x] + (a - (b*x^2 - c)*x^2)*y[x] == 0, y[1] == 0, y'[0] == 1};
sol = First@NDSolve[eq, y, {x, -2, 2}];
Plot[Evaluate[y[x] /. sol], {x, -2, 2}, PlotRange -> All, 
PlotLegends -> {"y(x)"}, AxesLabel -> {x, y[x]}]

enter image description here

MAPLE analytical solution:

enter image description here

y[x] == 
C[1]*HT[(2^(1/3)*3^(2/3)*(4*a*b + c^2))/(8*b^(4/3)), 
0, (-c*2^(1/3)*3^(1/3))/(2*b^(2/3)), (-2^(1/3)*3^(2/3)*b^(1/6)*x)/
3]*Exp[(x*(2*b*x^2 - 3*c))/(6*Sqrt[b])] + 
C[2]*HT[(2^(1/3)*3^(2/3)*(4*a*b + c^2))/(8*b^(4/3)), 
0, (-c*2^(1/3)*3^(1/3))/(2*b^(2/3)), (2^(1/3)*3^(2/3)*b^(1/6)*x)/
3]*Exp[(-(b*x^2 - 3/2*c)*x)/(3*Sqrt[b])]

You can be expressed this equation by the series:

$$y(x)=c_1 \text{HT1} \exp \left(\frac{x \left(2 b x^2-3 c\right)}{6 \sqrt{b}}\right)+c_2 \text{HT2} \exp \left(-\frac{\left(b x^2-\frac{3 c}{2}\right) x}{3 \sqrt{b}}\right)$$

were HT1 and HT2 is:

enter image description here


enter image description here

References for Triconfluent Heun function:

1.Decarreau, A.; Dumont-Lepage, M.C.; Maroni, P.; Robert, A.; and Ronveaux, A. "Formes Canoniques de Equations confluentes de l'equation de Heun". Annales de la Societe Scientifique de Bruxelles. Vol. 92 I-II, (1978): 53-78.

2.Ronveaux, A. ed. Heun's Differential Equations. Oxford University Press, 1995.

3.Slavyanov, S.Y., and Lay, W. Special Functions, A Unified Theory Based on Singularities. Oxford Mathematical Monographs, 2000.

| improve this answer | |

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.