3
$\begingroup$

I have used of these lines to plot three functions (in the first plotted figure) and I used of PlotLegend for them to be recognized.

In the second plot I have used of all written for the first plot except what written for PlotLegend.
For the first:

ttick = {\[Pi], 2 \[Pi]};
tstick = {\[Pi]/2, 3 \[Pi]/2};


plot123 = Plot[{Cos[t], Sin[t], Sin[t]*Cos[t]}, {t, 0, 2 \[Pi]}, 
PlotStyle -> {{Red, Thickness[0.008]}, {Blue, Thickness[0.008], 
 DotDashed}, {Green, Opacity[0.9], Thickness[0.01], 
 Dashing[Large]}}, Frame -> True,
 FrameStyle -> {{{Thickness[0.0054], 14, 
  Bold}, {Directive[Thickness[0.005]], 14, 
  Bold}}, {{Thickness[0.0055], 16, Bold}, {Thickness[0.005], 16, 
  Bold}}}, 
 FrameLabel -> {Style[t, Bold, Black, 18], 
 Style[C, Bold, Black, 15]}, 
 FrameTicks -> { {Automatic, None}, {ttick, tstick}}, 
 Epilog -> Inset[Text[Style["(a)", 16, Bold]], {2 \[Pi] - 0.3, 1.2}],
 PlotRange -> {All, {-1, 1.5}}, AspectRatio -> 0.65, 
 ImageSize -> 360, 
 PlotLegends -> 
 Placed[LineLegend[{"Cos", "Sin*Cos", "Sin"}, 
 LabelStyle -> {GrayLevel[0.1], Bold, 12}, 
 LegendLayout -> {"Row", 3}], {0.56, 0.85}]]

 Export["plot123.eps", plot123, ImageResolution -> 360]

enter image description here

For the second:

plot1 = Plot[Cos[t], {t, 0, 2 \[Pi]}, 
PlotStyle -> {Red, Thickness[0.008]}, Frame -> True, 
 FrameStyle -> {{{Thickness[0.0054], 14, 
  Bold}, {Directive[Thickness[0.005]], 14, 
  Bold}}, {{Thickness[0.0055], 16, Bold}, {Thickness[0.005], 16, 
  Bold}}}, 
 FrameLabel -> {Style[t, Bold, Black, 18], 
Style[C, Bold, Black, 15]}, 
 FrameTicks -> { {Automatic, None}, {ttick, tstick}}, 
 Epilog -> Inset[Text[Style["(b)", 16, Bold]], {2 \[Pi] - 0.3, 1.2}],
 PlotRange -> {All, {-1, 1.5}}, AspectRatio -> 0.65, 
 ImageSize -> 360]

 Export["plot1.eps", plot1, ImageResolution -> 360]

enter image description here

As it is clear, the quality of the first plot is too less than the second one. FrameTicks, plot colors and other things in the first is not as good as the second. How can I have a good plot although I use of plotlegend?!

$\endgroup$
5
$\begingroup$

The culprit here is not the legends, it is your usage of Opacity for one of the PlotStyle directives. EPS does not support opacity. Instead of warning you or simply ignoring the directive mathematica chooses to rasterize the whole image. (And evidently using a lossy compression no less )

FYI you can do this to see if you have an embedded raster in the eps:

 Select[Import["plot123.eps", "Lines"], 
    StringMatchQ[ # , "*" ~~ "<</Image" ~~ "*"] &]

{\<< ImageType 1/Width 1300/Height 995/BitsPerComponent ..

If you can use pdf, that works with the opacity.

Aside, check this out for some ways to make better dashed lines in eps/pdf Exporting EPS figures with dashing from ListPlot

$\endgroup$
  • 1
    $\begingroup$ I have validated george2079's answer. I made plot123 with and without Opacity. With Opacity the EPS is rasterized. Without Opacity it is a high quality vector plot. Issue is not related to PlotLegend $\endgroup$ – Jack LaVigne Sep 16 '15 at 20:29
  • $\begingroup$ @george2079, There is no word to show my knowledge of you, I was about to leave mathematica plotting but, your answer returned my hope $\endgroup$ – Unbelievable Sep 17 '15 at 7:14

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.