9
$\begingroup$

Consider the sum

sum1 = Sum[ k/( k^7 - 2 k + 3), {k, Infinity}]
-RootSum[ 2 + 5 #1 + 21 #1^2 + 35 #1^3 + 35 #1^4 + 21 #1^5 + 7 #1^6 + #1^7 &,
          ( PolyGamma[0, -#1] + PolyGamma[0, -#1] #1)/( 5 + 42 #1 + 105 #1^2 + 140 #1^3 
             + 105 #1^4 + 42 #1^5 + 7 #1^6)& ]

Back in the day of Mathematica 3.0 this same sum gave

sum2 = RootSum[( 3 - 2 #1 + #1^7) & , -(( PolyGamma[0, -#1] #1)/(-2 + 7 #1^6))& ]
-RootSum[ 3 - 2 #1 + #1^7 &, ( PolyGamma[0, -#1] #1)/(-2 + 7 #1^6)& ]

They are numerically equal

(sum1 - sum2) // N // Chop
0
  • Are the two RootSum expressions equivalent? and If so:
  • How do I manipulate/simplify sum1 result to the simpler form of sum2?
  • Why is the current result more complicated?
$\endgroup$
  • $\begingroup$ Answering your first question: those ARE numbers, not functions. So, if their numerical value is equal ... $\endgroup$ – Dr. belisarius Aug 15 '12 at 23:28
4
$\begingroup$

PolyGamma was modified in version 6 (see Summary of New Features in 6.0) as well as Sum last modified in version 7; therefore, the results of these sums are symbolically different. Perhaps sum1 is simpler than sum2 with respect to internal algebraic manipulations.

To verify equivalence you can make use of symbolic functionality, e.g.

RootApproximant[ sum1 - sum2 ]
0     

This may be enforced by numerical approximations to arbitrary order, e.g.

N[sum1, 3000] === N[sum2, 3000]
True
$\endgroup$
3
$\begingroup$

The first thing to notice is that

$$\begin{align*} \sum_{k=1}^\infty\frac{k}{k^7-2k+3}&=\sum_{k=0}^\infty\frac{k+1}{(k+1)^7-2(k+1)+3}\\ &=\sum_{k=0}^\infty\frac{k+1}{k^7+7 k^6+21 k^5+35 k^4+35 k^3+21 k^2+5 k+2} \end{align*}$$

The second thing you must know is that performing a full partial fraction decomposition on a rational function with an irreducible, high-degree denominator is not done through factoring(!!!), but through an implicit procedure known as Hermite reduction (see e.g. Bronstein).

In particular, the important formulae in this situation are

RootSum[Function[k, k^7 - 2 k + 3], Function @@ {k, n/((n - k) D[k^7 - 2 k + 3, k])}]
   n/(3 - 2 n + n^7)

compared with

RootSum[Function[k, 2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7], 
        Function @@ {k, 1/((n - k)
                        D[2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7, k])}]
   1/(2 + 5 n + 21 n^2 + 35 n^3 + 35 n^4 + 21 n^5 + 7 n^6 + n^7)

RootSum[Function[k, 2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7], 
        Function @@ {k, n/((n - k)
                        D[2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7, k])}]
   n/(2 + 5 n + 21 n^2 + 35 n^3 + 35 n^4 + 21 n^5 + 7 n^6 + n^7)

The reason for representing them in this way is that performing the summation with rational terms is as easy as replacing the n^j/(n - k) factor with -k^j PolyGamma[-k]; thus:

RootSum[Function[k, k^7 - 2 k + 3], 
        Function @@ {k, k/((n - k) D[k^7 - 2 k + 3, k]) /. n -> k - 1/PolyGamma[-k]}]
   -RootSum[3 - 2 #1 + #1^7 &, (PolyGamma[0, -#1] #1)/(-2 + 7 #1^6) &]

N[%, 25] == N[Sum[k/(k^7 - 2 k + 3), {k, 0, ∞}], 25]
   True

while

RootSum[Function[k, 2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7], 
        Function @@ {k, (n + 1)/((n - k)
                     D[2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7, k]) /.
                     n -> k - 1/PolyGamma[-k]}]
   -RootSum[2 + 5 #1 + 21 #1^2 + 35 #1^3 + 35 #1^4 + 21 #1^5 + 7 #1^6 + #1^7 &,
            (-1 + PolyGamma[0, -#1] + PolyGamma[0, -#1] #1)/
            (5 + 42 #1 + 105 #1^2 + 140 #1^3 + 105 #1^4 + 42 #1^5 + 7 #1^6) &]

N[%, 25] ==
N[Sum[(k + 1)/(2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7), {k, 0, ∞}], 25]
   True

The observant will instantly notice a dangling constant in the numerator, but this doesn't matter because

RootSum[Function[k, 2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7], 
        Function @@ {k, 1/D[2 + 5 k + 21 k^2 + 35 k^3 + 35 k^4 + 21 k^5 + 7 k^6 + k^7, k]}]
   0

(Exercise: why?)


An analogous discussion could be done for the case of integrating a rational function, with summation being replaced by integration, and the digamma function being replaced by a logarithm.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.