Parametric Region Plot

Question

I tried to find solution in a few discussions but I couldn't solve my problem because my knowledge is basic.

I have the following functions and parameters:

Mstar[d_, u_, p_] := ProductLog[-d p + p u];

PIstar[d_, u_, p_] := u - E^-Mstar[d, u, p] (u - d);

CMstar[d_, u_, p_] := 1/2 Mstar[d, u, p]^2;

EUY1star[d_, u_, p_] := PIstar[d, u, p] p - CMstar[d, u, p];

EUB1star[d_, u_, p_, r_, s_] := r (1 - PIstar[d, u, p]) - 2 PIstar[d, u, p] s r;

EUB2star[d_, u_, p_, r_, s_] := r (1 - d) - 3 d s r - EUY1star[d, u, p];

d = 0.2;
u = 0.8;
r = 1;

and I want to draw the Parametric Region Plot of

[{EUB2star[d, u, p, r, s] - EUB1star[d, u, p, r, s] > 0 && EUB2star[d, u, p, r, s] > 0}, {p, 0, 1000}]

where in the horizontal axis I need PIstar[d, u, p] and in the vertical axis {s, 0, 2}.

I have no idea how to do it yet in my V.8. Pls help. Maurizio.

Answer 1

RegionPlot[{EUB2star[d, u, p, r, s] - EUB1star[d, u, p, r, s] > 0 && 
           EUB2star[d, u, p, r, s] > 0}, 
           {p, 0, 2}, {s, 0, 2}]

Answer 2

Version 2

How about writing all your function in terms of $\pi^*$ and then plotting them from 0.2 to 0.8 like this

 region = RegionPlot[{r (1 - d) - 
  3 d s r - (pstar*(Log[(u - d)/(u - pstar)]/(u - 
         pstar)) - (Log[(u - d)/(u - pstar)])) - (r (1 - pstar) - 
    2 pstar*s r) > 0 && 
  r (1 - d) - 
  3 d s r - (pstar (Log[(u - d)/(u - pstar)]/(u - 
         pstar)) - (Log[(u - d)/(u - pstar)])) > 0}, {pstar, 0.2, 
  0.8}, {s, 0, 2}, MaxRecursion -> 10, 
 FrameLabel -> {"\!\(\*SuperscriptBox[\(\[Pi]\), \(*\)]\)", "s"}, 
  RotateLabel -> False, LabelStyle -> (FontSize -> 20)]

For the transformation I used the inverse function for ProductLog

If $b = ProductLog(a)$ then $a = b*e^{b}$

Using above we can write

$$p(u-d)=M^* e^{M^*}$$

This allows to write $p$ in terms of $\pi^*$

$$M^* = Log\left(\frac{u-d}{u-\pi^*}\right)$$

$$p= \frac{1}{u-\pi^*}Log\left(\frac{u-d}{u-\pi^*}\right)$$

With the above transformation you can express all your inequality in terms of $\pi^*$. Since $\pi^*$ ranges from $u$ to $d$ for $p$ going from $0$ to $\infty$, you can then RegionPlot $\pi^*$ from u to d. This is what I have shown.

---

Can't you just find the range of $\pi^*$ for the range of $p$ and then plot over that range.

  regPlot[pmax_, smax_] := 
  Module[{pmin = 0, smin = 0, PIstarMin, PIstarMax},

  PIstarMin = PIstar[d, u, pmin];
  PIstarMax = PIstar[d, u, pmax];

  RegionPlot[{EUB2star[d, u, p, r, s] - EUB1star[d, u, p, r, s] > 0 &&
  EUB2star[d, u, p, r, s] > 0}, {p, PIstarMin, PIstarMax}, {s, 0, 
  smax}, MaxRecursion -> 10, 
  FrameLabel -> {"\!\(\*SuperscriptBox[\(\[Pi]\), \(*\)]\)", "s"}, 
   RotateLabel -> False, LabelStyle -> (FontSize -> 20)]]

So for $p_{max}=1000$ and $s_{max}=2$ we get

   regPlot[1000, 2]