2
$\begingroup$
Reduce[
  Abs[-((4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] +
  Abs[-((4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] < 1 , Abs[p]]

It is taking lot of time. It is running. Can any one help to reduce the inequality?

$\endgroup$
6
  • 1
    $\begingroup$ There won't be a nice form. If you Plot3D it, you'll see that the region you seek is really rather a horrible shape. Do you have any more information about $p, q$? $\endgroup$ Aug 28 '15 at 7:47
  • $\begingroup$ I can consider p and q each having modulus less than 1. How to get the 3Dplot ? Could you please provide me the code? $\endgroup$ Aug 28 '15 at 8:18
  • $\begingroup$ If you look in the documentation for Plot3D, you'll find out. Plot3D[Abs[(4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2] + Abs[(4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2], {p, -5, 5}, {q, -5, 5}] This is of course for real $p, q$ only. $\endgroup$ Aug 28 '15 at 8:20
  • $\begingroup$ But even the reduction is taking a lot of time. Is there any way to get it faster? $\endgroup$ Aug 28 '15 at 8:30
  • $\begingroup$ @belisarius $p, q$ are possibly complex, I think. $\endgroup$ Aug 28 '15 at 9:11
4
$\begingroup$

Because the question seeks an expression for the modulus of p, it makes sense to express p and q in terms of the moduli and phases.

sim = Simplify[(Abs[-((4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] + 
                Abs[-((4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2)]) /. 
          {p -> pm Exp[I pp], q -> qm Exp[I qp]}, pm >= 0 && qm >= 0 && (pp | qp) ∈ Reals]
(* (4 (pm + qm))/Abs[-1 + Sqrt[1 + 4 E^(I pp) pm + 4 E^(I qp) qm]]^2 *)

In what follows, we explore sim <= 1 instead of the question's sim < 1 in order to obtain solutions at the boundary, sim == 1, which is where most solutions seem to lie. Although

Reduce[sim <= 1 && pm >= 0 && qm >= 0, pm]

still produced no answer, even after 19 hours, the special case of setting qp to π did. Some hand-holding was required, however.

Reduce[(sim /. {qp -> Pi}) <= 1 && 2 π > pp >= 0 && pm >= 0 && qm >= 0, pm]

returned unevaluated with the message

Reduce::nsmet: This system cannot be solved with the methods available to Reduce. >>

However,

Reduce[FullSimplify[Reduce[(sim /. {qp -> Pi}) <= 1 && pm >= 0 && qm >= 0, pm], 
    2 Pi > pp >= 0 && pm >= 0 && qm >= 0] && 2 Pi > pp >= 0 && pm >= 0 && qm >= 0, pm]

did produce a meaningful answer.

(* (0 <= pp < 2 π && qm >= 1/4 && pm == 0) || (pp == π && qm >= 1/4 && pm >= 0) || 
   (pp == π && ((qm > 1/4 && pm >= 0) || (0 <= qm <= 1/4 && pm >= 1/4 (1 - 4 qm)))) *)

Note that, except for the solution pm == 0, all these solutions require pp == π.

In summary, solutions are available for qp -> π and perhaps other cases. Whether a solution can be obtained in general within several hours of computation is unknown.

$\endgroup$
1
  • $\begingroup$ Unless I made a mistake in my calculations I have the general form for $p$ and $q$ negative reals. Would you be so kind as to have a look at my (non-randomized) answer? $\endgroup$
    – A.G.
    Apr 26 at 15:31
1
$\begingroup$

Using Mathematica as a tool for investigation suggests that no solution exists for $\text{"your expression"}<1$. If this is true, one would expect Reduce to return {}, albeit after a long time.

Here is a randomized exploration of 1,000,000 pairs of complex numbers with real and imaginary parts between -1000 and 1000:

f[{p_, q_}] := 
   Abs[-((4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] + 
   Abs[-((4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2)];
sample = With[{n = 1000000, a = 1000},
   RandomComplex[{-a - a I, a + a I}, {n, 2}]];
data = f /@ sample;
Min[data]
Histogram[ Log@data]

enter image description here

$\endgroup$
2
  • 1
    $\begingroup$ Shall do, but probably late today or tomorrow morning. $\endgroup$
    – bbgodfrey
    Apr 26 at 20:58
  • 1
    $\begingroup$ Your two answers are very good, I believe. I wish that I had more time to review them in detail. $\endgroup$
    – bbgodfrey
    Apr 28 at 4:53
1
$\begingroup$

You want to find solutions to the strict inequality $$ \left| \frac{-4 p}{\left(\sqrt{4 p+4 q+1}-1\right)^2}\right| + \left| \frac{-4 q}{\left(\sqrt{4 p+4 q+1}-1\right)^2}\right| <1. $$ You can simplify a bit by replacing $4p$ and $4q$ by $p$ and $q$ and removing negative signs inside Abs: $$ \left| \frac{p}{\left(\sqrt{p+q+1}-1\right)^2}\right| + \left| \frac{q}{\left(\sqrt{p+q+1}-1\right)^2}\right|= \frac{|p|+|q|}{\left|\sqrt{p+q+1}-1\right|^2}<1 $$ which is equivalent to \begin{align} |p|+|q| &< |\sqrt{p+q+1}-1|^2\\ &=(\sqrt{p+q+1}-1)\overline{(\sqrt{p+q+1}-1)}\\ &=(\sqrt{p+q+1}-1)(\overline{\sqrt{p+q+1}}-1). \end{align} First consider the case where $p+q+1\in \mathbb C\setminus \mathbb R_-$, then we can replace the last factor by $$ \overline{\sqrt{p+q+1}}-1 ={\sqrt{\overline {p+q+1}}}-1 ={\sqrt{\overline p+\overline q+1}}-1. $$ In this case, we ask

Reduce[
  Abs[p] + Abs[q] 
  < (Sqrt[p + q + 1] - 1) ( Sqrt[p\[Conjugate] + q\[Conjugate] + 1] - 1), 
  {p, q}]
(* False *)

If on the other hand $p+q+1\in \mathbb R_-$ then:

Reduce[Abs[p] + Abs[q] < (Sqrt[r] - 1)^2 
  && p + q + 1 == r && r <= 0 && r \[Element] Reals, {p, q, r}]
(* False *)

and we can conclude that there are no solutions.

Non-strict version

Following the same line we look at two cases:

Reduce[Abs[p] + Abs[q] <=  
(Sqrt[p + q + 1] - 1)(Sqrt[p\[Conjugate] + q\[Conjugate] + 1] - 1), {p, q}]
(* 
 (-1 < p < 0 && q == -1 - p) || 
 (p == -1 && q == 0) || (p == 0 && (q == -1 || q == 0)) 
*)

and

Reduce[Abs[p] + Abs[q] <= (Sqrt[r] - 1)^2 
   && p + q + 1 == r && r <= 0 && r \[Element] Reals, {p, q, r}]
(*
((-1 < p < 0 && q == -1 - p) || (p == -1 && q == 0) || 
  (p == 0 && q == -1)) && r == 1 + p + q
*)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.