Coloring image components according to their area

Question

I have a rasterized image img that is created by this code:

img =  
   Image @ 
      Graphics[
        {Disk[], Disk[{4, 4}, 1.5], Disk[{-4, 5}, 2], Disk[{0, -6}, 4]},
        PlotRange -> 11]

I want to color the circles depending on their size (near white for the biggest, going through darker grays until the smallest gets colored black, or something similar).

I know it has something to do with MorphologicalComponents, but I don't know how to colorize the different components.

EDIT:

Actually the input image was not the circle one, it was this:

And when I run your code, even though the points image gets good results, this one gives some error. The output is this:

Which doesn't recognize the areas of any squares.

Answer 1

You can use ArrayPlot

ArrayPlot[MorphologicalComponents[ColorNegate[i]]]

or you can use a ColorFunction. Here is a version for the second input image with the smaller regions using darker colors.

mimg = MorphologicalComponents[Import["http://i.stack.imgur.com/w4FkO.png"]];
map = Thread[
   Ordering@ComponentMeasurements[mimg, "Area"][[All, 2]] -> 
    Range[Max[mimg]]];
areas = mimg /. map;
Colorize[areas, ColorFunction -> "GrayTones"]

Answer 2

I started with ciao's code, but I didn't like the way the gray level values were obtained, so I re-worked his code to this:

img = 
  Image @ 
    Graphics[
      {Disk[], Disk[{4, 4}, 1.5], Disk[{-4, 5}, 2], Disk[{0, -6}, 4]},
      PlotRange -> 11]

With[{m = MorphologicalComponents[ColorNegate @ Binarize @ img]},
   Module[{items, n, areas, lvls},
     items = ComponentMeasurements[m, "FilledCount"];
     n = Length @ items;
     areas = items[[All, 2]];
     lvls = 
       Thread[
         Rule[
           Range @ n, 
           GrayLevel @ Sqrt @ Rescale[#, MinMax[areas], {.05, .85}] & /@ areas]];
     Colorize[m, ColorRules -> Join[{0 -> White}, lvls]]]]

Answer 3

Sorry for my poor English to may be failure understand demand of your question.And as I understand the curently accepted answer have not at par slightly?

---

• The first question

color the circles depending on their size (near white for the biggest, going through darker grays until the smallest gets colored black, or something similar)

This is my solution

img = Import["http://i.stack.imgur.com/CqRZd.png"] // ColorNegate;
MorphologicalComponents[img] // 
 Colorize[#, 
   ColorRules -> 
    Prepend[Normal[
      Blend[{Black, 
          White}, #] & /@ (ComponentMeasurements[img, "Area"] // 
          Association // (# - Min[#])/(Max[#] - Min[#]) &)], 
     0 -> Red]] &

(I set the background red is for conveniently looking the circle of White to Black,otherwise your white circle will be invisible.)

---

• The second question

Which doesn't recognize the areas of any squares.

So you just colorize the squares or I take a wrong interpretation?But those place isn't a squres?

So I post a solution like follow

array = MorphologicalComponents[
   pic = Import["http://i.stack.imgur.com/w4FkO.png"]];
effect = SelectComponents[
   array, {"PerimeterLength", 
    "EquivalentDiskRadius"}, #/#2 - (4*Sqrt[Pi] // N) <= 2.8 &] // 
  Colorize[#, 
    ColorRules -> 
     Prepend[Normal[
       Blend[{Black, 
           White}, #] & /@ (ComponentMeasurements[#, "Area"] // 
           Association // (# - Min[#])/(Max[#] - Min[#]) &)], 
      0 -> Red]] &

ImageCompose[pic, {effect, 0.8}]