Problem exporting and re-importing STL file

Question

I wrote all code and there're no errors in code. Result of code is like first picture(left). But I can't Import that structure. The result of import stl file is second one(right one). How can I import it?(i think it's because i used table at that part)

Code is here

repeatingUnit = Hexahedron[
   (*bottom*){{-2, -2, 0}, {-2, 2, 0}, {2, 2, 0}, {2, -2, 0},
    (*top*){-3, -3, 3}, {-3, 3, 3}, {3, 3, 3}, {3, -3, 3}}];

a = Graphics3D[
   Table[
    GeometricTransformation[
     repeatingUnit,
     TranslationTransform[{0, 0, n}]
     ], {n, 0, 21, 3}], Axes -> True];
v = {{-2, -2, 0}, {-2, 2, 0}, {2, 2, 0},
   {2, -2, 0}, {-3, -3, -12}, {-3, 3, -12}, {3, 3, -12}, {3, -3, -12}};
i = {{1, 2, 3, 4}, {1, 2, 6, 5}, {2, 3, 7, 6}, {3, 4, 8, 7}, {4, 1, 5,
     8}, {5, 6, 7, 8}};
b = Graphics3D[{GraphicsComplex[v, Polygon[i]]}, Axes -> True];
v2 = {{-1, -1, 25}, {-1, 1, 25}, {1, 1, 25}, {1, -1, 25}, {-1.7, -1.7,
     27.5}, {-1.7, 1.7, 27.5}, {1.7, 1.7, 27.5}, {1.7, -1.7, 27.5}};
i2 = {{1, 2, 3, 4}, {1, 2, 6, 5}, {2, 3, 7, 6}, {3, 4, 8, 7}, {4, 1, 
    5, 8}, {5, 6, 7, 8}};
c = Graphics3D[{GraphicsComplex[v2, Polygon[i2]]}, Axes -> True];
d = Graphics3D[Cylinder[{{0, 0, 27.5}, {0, 0, 31}}, 1/4]];
e = Graphics3D[Cylinder[{{0, 0, 31}, {0, 0, 33}}, 1/8]];
f = Graphics3D[Cuboid[{1, -1, 24}, {-1, 1, 25}]];
gj = Show[a, b, c, d, e, f]


Export["building.stl", gj]
Import["building.stl"]

Answer 1

Exporting a 3D graphic that contains more than one Hexahedron object doesn't seem to work. The problem seems to stem from the fact that Export calls DiscretizeGraphics on the Graphics3D object, and DiscretizeGraphics can't handle the input. Both Export and ExportString work (i.e. fail) in the same way:

ExportString[Graphics3D[{Hexahedron[], Hexahedron[]}], "STL"]

DiscretizeGraphics::rnimpl: The function DiscretizeGraphics is not implemented for . >>

Export::type: Graphics3D cannot be exported to the STL format. >>

$Failed

Unfortunately, when the same happens within a call to Export with a more complex Graphics3D input, the system fails silently, and just returns whatever part of the original input it was able to process. This is what the OP observed.

---

A solution to this is not to use Hexahedron primitives in the construction of the model. In fact, the OP already had a primitive similar to the desired repeating unit coded as a Polygon object which exported fine.

In the following I will use the OP's definitions for b, c, d, e, f. I can then redefine the repeating unit of the building model a using a simple Polygon:

vrep = {
         (* vertices on bottom face*)
         {-2, -2, 0}, {-2, 2, 0}, {2, 2, 0}, {2, -2, 0}, 
         (* vertices on top face*)
         {-3, -3, 3}, {-3, 3, 3}, {3, 3, 3}, {3, -3, 3}
       };

irep = {
         {1, 2, 3, 4}, 
         {1, 2, 6, 5}, 
         {2, 3, 7, 6}, 
         {3, 4, 8, 7}, 
         {4, 1, 5, 8}, 
         {5, 6, 7, 8}
       };

a = Graphics3D[
      Table[
         GeometricTransformation[
            GraphicsComplex[vrep, Polygon[irep]],
            TranslationTransform[{0, 0, n}]
         ],
         {n, 0, 21, 3}
      ],
      Axes -> True
    ];

Once we have this new definition, we can use the rest of your code. The result is unchanged within Mathematica. The big difference, however, is the fact that now Export to an STL file seems to work!

gj = Show[a, b, c, d, e, f];
Export["building.stl", gj]; 

GraphicsRow[{gj, Import["building.stl"]}, ImageSize -> Full]