2
$\begingroup$

How can we simplify the solution in:

DSolve[ {Sqrt[ 1 - (r[t] - T^2/r[t])^2/(2 a)^2]/(r[t] - T^2/r[t])/(2 a) == 
r'[t]/ r[t], r[0] == T}, r, t]

(r,t) are polar coordinates.

EDIT1:

Second order ODE in terms of $\psi, r, \theta $ which respectively are: angle between arc and radius vector and the polar coordinates. ( Constants T > a)

$$ \psi^{''}(s)= \dfrac{T^2 \cos \psi}{2 \,a \,r(s)^3} $$

$$ \dfrac {d \theta}{ds}=\dfrac{\sin \psi}{ r(s)} = \dfrac{1-T^2/a^2}{2 a} $$

$$ \dfrac {d r}{ds}=\cos \psi $$

Boundary Conditions:

$$ @ r= T, \psi(0) = \psi^{'}(0) =0 , \psi^{''}(0)= -1/ (2 a T). $$

Had no luck at start, trying..

Thanks in advance

EDIT 2:

Corrected errors, and now it works:

$$ \psi^{''}(s)= \dfrac{-T^2 \cos \psi}{ a \,r^3(s)} $$

Boundary Conditions:

$$ @ r= T, \psi(0) = 0, \,\psi^{'}(0) =1/a. $$

T = 4; a = 3; ri = T; smax = 2 Pi a;

    CIRC = {SI''[s] == -(T^2/a ) Cos[SI[s]]/R[s]^3, SI'[0] == 1/a, 
       SI[0] == 0, R'[s] == Cos[SI[s]], R[0] == ri, 
       TH'[s] == Sin[SI[s]]/R[s], TH[0] == 0};

    NDSolve[CIRC, {SI, R, TH}, {s, 0, smax}];

    {si[u_], r[u_], th[u_]} = {SI[u], R[u], TH[u]} /. First[%];

    CENTRAL =  ParametricPlot[T { Cos[v], Sin[v]}, {v, .0, 2 Pi}, 
      PlotStyle -> {Purple, Thick}]

    ECC = ParametricPlot[{r[s] Cos[th[s]], r[s] Sin[th[s]]}, {s, .0, 
       smax}, PlotLabel -> ECCENTRIC_CIRCLE, PlotStyle -> {Red, Thick}, 
      GridLines -> Automatic, AspectRatio -> Automatic, PlotRange -> All]

    Show[ECC, CENTRAL]
$\endgroup$
8
  • 1
    $\begingroup$ What do you mean by "simplify the solution"? What do you get now; what would you like to get? For what purpose would you like to use the solution? $\endgroup$
    – MarcoB
    Commented Aug 19, 2015 at 20:44
  • $\begingroup$ The solution is lengthy so did not transfer it here. Even if boundary condition is taken as r[0]== r1, it is still unwieldy. The square root has two signs here, one for the convex and other concave part. Reference is math.stackexchange.com/questions/1398614/…, where we can further show the result applies to two different parts of same curve or circle. Much appreciate any help to express it (r-t) form also. $\endgroup$
    – Narasimham
    Commented Aug 19, 2015 at 21:14
  • $\begingroup$ Have you tried to use e.g. ParametricNDSolve to check that at least the equation is well-formed and it represents what you expect? $\endgroup$
    – MarcoB
    Commented Aug 19, 2015 at 21:23
  • $\begingroup$ I tried NDSolve only. Even at r=r1 as BC it wont take off. At r=T ,it is a tougher start. $\endgroup$
    – Narasimham
    Commented Aug 19, 2015 at 21:36
  • $\begingroup$ It occurs to me just now, I shall raise it to second order and try, it often works. $\endgroup$
    – Narasimham
    Commented Aug 19, 2015 at 21:47

1 Answer 1

8
$\begingroup$

The code in this question can be written as

eq = Sqrt[1 - (r[t] - T^2/r[t])^2/(2 a)^2]/(r[t] - T^2/r[t])/(2 a) == r'[t]/r[t];
DSolveValue[{eq, r[0] == T}, r[t], t] // FullSimplify
(* InverseFunction[((-Sqrt[-T^4] ArcTan[(2 a^2 + T^2 - #1^2)/
     Sqrt[4 a^2 #1^2 - (-T^2 + #1^2)^2]] + T^2 (-2 Log[#1] + 
     Log[-2 T^4 + 2 (2 a^2 + T^2) #1^2 + 
     2 Sqrt[-T^4] Sqrt[4 a^2 #1^2 - (-T^2 + #1^2)^2]])) 
     Sqrt[4 a^2 #1^2 - (-T^2 + #1^2)^2])/(
     2 Sqrt[-T^4] #1 Sqrt[(4 a^2 #1^2 - (-T^2 + #1^2)^2)/(a^2 #1^2)]) &][(
     t T^3 - 2 a (a T^3 ArcTan[a/T] + Sqrt[a^2 T^2] Sqrt[-T^4] (-2 Log[T] + 
     Log[4 (a^2 T^2 + Sqrt[a^2 T^2] Sqrt[-T^4])])))/(4 a T^3)] *)

which, as noted by the OP, is quite complicated.

Alternatively, this problem can be solved using Integrate, because the equation is first order and t does not appear explicitly. Define

exp = eq[[1]] r[t] /. {r[t] -> a r0, T -> a T}
(* (r0 Sqrt[1 - (a r0 - (a T^2)/r0)^2/(4 a^2)])/(2 (a r0 - (a T^2)/r0)) *)

which replaces r[t] by r0 and rescales r0 and t by a. Then, note the turning points of this expression.

Solve[exp == 0, r0]
(* {{r0 -> -1 - Sqrt[1 + T^2]}, {r0 -> 1 - Sqrt[1 + T^2]}, 
    {r0 -> -1 + Sqrt[1 + T^2]}, {r0 -> 1 + Sqrt[1 + T^2]}} *)

Since the minimum value of r0 is given in the question as T, which we assume to be positive, the turning point of interest is the last one, 1 + Sqrt[1 + T^2], beyond which the integral will become complex. Now, perform the integral in this region to obtain t as a function of r.

t = Integrate[1/exp, {r0, T, r}, Assumptions -> 0 < T < r < 1 + Sqrt[1 + T^2]]
(* -2 I a (2 Log[r] + Log[2 - 2 I T] + Log[-4 + 4 I T] - 
     Log[2 - r^2 + T^2 - I Sqrt[-r^4 - T^4 + 2 r^2 (2 + T^2)]] - 
     Log[2 T^4 - 2 r^2 (2 + T^2) + 2 I T^2 Sqrt[-r^4 - T^4 + 2 r^2 (2 + T^2)]]) *)

Although complicated, it is far less so that the DSolve expression. Also, rescaling t by a eliminates a from the expression, leaving (the rescaled) T as the only free parameter. As an example of the form of this solution, plot it with T -> 1.

ParametricPlot[{(t/a) /. {T -> 1}, r}, {r, 1, 4}, 
  AspectRatio -> 1/GoldenRatio, AxesLabel -> {"t/a", "r/a"}]

enter image description here

The curve stops at the turning point, r/a = 1 + Sqrt[2].

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.