2
$\begingroup$

See these example, why does the output is different?

expr = Root[-7 a^4 #1^2 - 2 a^2 #1^4 + #1^6 &, 4];
expr /. a -> 1 // N
ToRadicals@expr /. a -> 1 // N

1.95663668695703

0 . - 1.35219344945396 I

Table[Hypergeometric2F1[1/2-n/2,1-n/2,1-n,-4],{n,5}]
Table[Hypergeometric2F1[1/2-n/2,1-n/2,1-n,-4]//FullSimplify//Evaluate,{n,5}]//RootReduce

{1, 1, 2, 3, 5}

{1/10 (5 + Sqrt[5]), 1/10 (5 + 3 Sqrt[5]), 1/5 (5 + 2 Sqrt[5]), 1/10 (15 + 7 Sqrt[5]), 1/10 (25 + 11 Sqrt[5])}

$\endgroup$
  • $\begingroup$ The ordering of the roots depends on a. So I think the order of operations not being commutative is probably an explanation of the first difference. (See Root, "Details".) $\endgroup$ – Michael E2 Aug 19 '15 at 16:52
4
$\begingroup$

Part1.

The ordering of the roots and consequently which is the fourth root depends on when a is given its value.

Table[Root[-7 a^4 #1^2 - 2 a^2 #1^4 + #1^6 &, n] // ToRadicals, {n, 6}] /. 
 a -> 1.

{0, 0, 0. + 1.35219 I, 0. - 1.35219 I, 1.95664, -1.95664}

Table[Root[-7 a^4 #1^2 - 2 a^2 #1^4 + #1^6 &, n] /. a -> 1. // ToRadicals, {n,
   6}]

{-1.95664, 0., 0., 1.95664, 0. - 1.35219 I, 0. + 1.35219 I}

Part 2.

Clear[f]

f[n_, x_] = Hypergeometric2F1[1/2 - n/2, 1 - n/2, 1 - n, x];

From the definition of Hypergeometric2F1 you can see that the sum f[n, -4] does not converge in general

Sum[Pochhammer[1/2 - n/2, m] Pochhammer[1 - n/2, m]/
   Pochhammer[1 - n, m] (-4)^m/m!, {m, 0, Infinity}]

Sum::div: Sum does not converge. >>

Sum[((-4)^m*Pochhammer[1/2 - n/2, m]*Pochhammer[1 - n/2, m])/ (m!*Pochhammer[1 - n, m]), {m, 0, Infinity}]

However, it has a "Borel" regularized value

Sum[Pochhammer[1/2 - n/2, m] Pochhammer[1 - n/2, m]/
   Pochhammer[1 - n, m] (-4)^m/m!, {m, 0, Infinity}, 
 Regularization -> "Borel"]

((1/2)*(1 + Sqrt[5]))^n/Sqrt[5]

This is the value used by FunctionExpand or FullSimplify

f[n, -4] // FunctionExpand // Simplify

((1/2)*(1 + Sqrt[5]))^n/Sqrt[5]

f[n, -4] // FullSimplify

((1/2)*(1 + Sqrt[5]))^n/Sqrt[5]

However, for n an explicit positive integer the Pochhammer symbols in the numerator stop the sum with a zero term and results in a polynomial

Table[{n, f[n, x]}, {n, 5}]

{{1, 1}, {2, 1}, {3, (4 - x)/4}, {4, (2 - x)/2}, {5, (1/16)*(16 - 12*x + x^2)}}

list1 = (% /. x -> -4)

{{1, 1}, {2, 1}, {3, 2}, {4, 3}, {5, 5}}

These polynomials are truncations of (hence not equal to) the Borel regularized infinite series

list2 = Transpose[{Range[5], 
   Table[f[n, -4] // FunctionExpand // Simplify // Evaluate, {n, 5}] // 
     RootReduce // Simplify}]

{{1, (1/10)(5 + Sqrt[5])}, {2, (1/10)(5 + 3*Sqrt[5])}, {3, 1 + 2/Sqrt[5]}, {4, 3/2 + 7/(2*Sqrt[5])}, {5, 5/2 + 11/(2*Sqrt[5])}}

This approaches the integer values of n as a limit

list2 == Table[{m, Limit[f[n, -4] // FullSimplify // Evaluate, n -> m]}, {m, 
   5}]

True

Plot[f[n, -4], {n, 0, 5},
 Epilog -> {AbsolutePointSize[4], Red, Point[list1], Blue, Point[list2]}]

enter image description here

Note that the polynomial gets closer to the Borel regularized infinite series as n increases, i.e., as the order (number of terms) of the polynomial increases.

$\endgroup$
  • $\begingroup$ More conventionally, one uses the integral representation of the Gaussian hypergeometric function as the analytic continuation off the unit disk. $\endgroup$ – J. M. is away Aug 19 '15 at 18:51

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.