6
$\begingroup$

Suppose that I use:

Text[Style["(1, 0, 0)", 12, Background -> White], {1, 1, 0}]

How can I put a few points of padding around the text?

Thanks to Jens:

Initialization cell:

Options[myText] = {Background -> White, Padding -> 1, FrameStyle -> None};

myText[s_, pos_, OptionsPattern[]] := 
 Text[Framed[Style[s, 12], Background -> OptionValue[Background], 
   FrameMargins -> OptionValue[Padding], 
   FrameStyle -> OptionValue[FrameStyle]], pos]

Image code using myText:

Show[
 ContourPlot3D[{z == Sqrt[x^2 + y^2]}, {x, -2.5, 2.5}, {y, -2.5, 
   2.5}, {z, 0, 2},
  ContourStyle -> {Yellow, Opacity[0.8]}, Mesh -> None],
 ParametricPlot3D[{r Cos[t], r Sin[t], 2}, {t, 0, 2 π}, {r, 0, 2},
   PlotStyle -> {Blue, Opacity[0.5]}, Mesh -> None],
 ParametricPlot3D[{r Cos[t], r Sin[t], 0}, {t, 0, 2 π}, {r, 0, 2},
   PlotStyle -> {LightBlue, Opacity[0.5]}, Mesh -> None],
 Graphics3D[{
   Red, Thick, Arrow[{{0, 0, 0}, {2, 2, 0}}],
   Black, PointSize[Large],
   Point[{{0, 0, 0}, 2 {Cos[Pi/4], Sin[Pi/4], 0}}],
   myText["r = 0", {0, -0.6, 0}],
   myText["r = 2", 2 {Cos[30 °], Sin[30 °], 0}],
   Red, Thick, 
   Arrow[{{Cos[Pi/4], Sin[Pi/4], 0}, {Cos[Pi/4], Sin[Pi/4], 2.5}}],
   Black, PointSize[Large],
   Point[{{Cos[Pi/4], Sin[Pi/4], 0}, {Cos[Pi/4], Sin[Pi/4], 
      1}, {Cos[Pi/4], Sin[Pi/4], 2}}],
   myText["z = r", {Cos[35 °], Sin[35 °], 0.8}],
   myText["z = 2", {Cos[35 °], Sin[35 °], 1.8}]
   }], AxesLabel -> {"x", "y", "z"}, 
 PlotRange -> {{-2.5, 2.5}, {-2.5, 2.5}, {0, 2.5}}
 ]

For some reason, I am getting frequent kernel beeps when running the cell containing the image code. I don't know why.

enter image description here

$\endgroup$
  • 1
    $\begingroup$ Could you provide some context for your problem? E.g. Are you trying to include this text inside a graphic, or is it intended to be free-standing? $\endgroup$ – MarcoB Aug 17 '15 at 3:49
  • $\begingroup$ @MarcoB Jens has the idea that I need. Thanks. $\endgroup$ – David Aug 17 '15 at 3:59
10
$\begingroup$

There are two alternatives I would suggest, depending on what your plans for the Background are. Here is an illustration:

Text[Pane[Style["(1, 0, 0)", 12, Background -> Yellow], 
  ImageMargins -> 10], {1, 1, 0}]

small background

Text[Framed[Style["(1, 0, 0)", 12], Background -> Yellow, 
  FrameMargins -> 10, FrameStyle -> None], {1, 1, 0}]

big background

The first solution uses a Pane, but this doesn't have a Background option so that you have to specify the background color in the Style command, as you already did. I changed it to yellow just for clarity.

The second solution assumes that you want the background to fill out the extra space that was created, too. This can be done with Frame because it allows the Background option. I then set FrameStyle -> None to make the result look otherwise indistinguishable from a Pane.

When used in Graphics3D, these two outputs look as follows:

pane

enter image description here

To make this easier to use, just define something like this:

Options[myText] = {Background -> White, Padding -> 5, 
   FrameStyle -> None};

myText[s_, pos_, OptionsPattern[]] := 
 Text[Framed[Style[s, 12], Background -> OptionValue[Background], 
   FrameMargins -> OptionValue[Padding], 
   FrameStyle -> OptionValue[FrameStyle]], pos]

Graphics3D[myText["{1,0,0}", {0, 0, 0}], Background -> LightBlue]

function

The relevant options can be changed by adding them to in the invocation of myText. I used the name Padding for the option that you wanted, even though it's realized as FrameMargins internally.

$\endgroup$
  • $\begingroup$ I think this is what I need. However, that's a lot of stuff to type each time you want to put a label in your diagram. Is it possible for a single line of code (and where to put it, initialization or whatever) so that every time I typed something like Text["(1,0,0)",{1,0,0}] all that other stuff would get filled in? Or is there a way to minimize some of it? Thanks for the help. $\endgroup$ – David Aug 17 '15 at 4:02
  • $\begingroup$ Sure, your best bet is to define a function. I'll add that... $\endgroup$ – Jens Aug 17 '15 at 4:09
  • $\begingroup$ Did you define myText as you did with all those OptionValues so that you can override the options later with something like Options[myText] = {Background -> Yellow, Padding -> 1, FrameStyle -> None}; And would you put your original code in initialization cells at the top of your notebook or what? $\endgroup$ – David Aug 17 '15 at 4:49
  • $\begingroup$ Yes to both. E.g., try Graphics3D[myText["{1,0,0}",{0,0,0},Padding->20,Background->Directive[Opacity[.5],Red]],Background->LightBlue]. Or SetOptions[myText,Background->LightOrange]. $\endgroup$ – Jens Aug 17 '15 at 4:58
  • $\begingroup$ Showed an example of how I am using your idea. See my original post above. $\endgroup$ – David Aug 17 '15 at 15:28

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.