Replacing the Slot in an expression

Question

So I've got Mathematica to handle the grunt work for me to obtain expression:

Root[ (* blah, blah *) + #^2 + (* etc, etc *)  ]

Now, the value inside Root is a polynomial whose all coefficients are at a range of values that Root cannot evaluate symbolically. I actually tried to it forcefully (that is, numerically), but the computer just keeps at it for hours. So I gave up on that.

Anyways, for further processing, I just extract the arguments of Root -- which can be done with function substitution and a some simple text manipulation:

sol = (* blah, blah *) + #^2 + (* etc, etc *)

Then I want to replace slot # and other slots so I can then apply more operations. And, this is where I get stuck... I don't know how to do it. I've tried:

sol & [x]   (* say I want all # to be x *)

So how do I do this?

EDIT: I've editted #3 to #. I really don't know why I didn't do so in the first place, but I soon as I noticed possible misconstrusion, I just panicked.

Answer 1

I think this is what you're trying to get at. Say you're solving an equation that generates Root expressions:

solution = Solve[x^5 - x^4 + 13 == 0, x]

This gives a list of rules with a number of Root expression solutions. Let's just take a look at the first one, for simplicity:

firstroot = x /. First[solution] (* gives: Root[13 - #1^4 + #1^5 & , 1, 0] *)

Now you want just the first argument of this Root expression:

rootfunction = First[firstroot] (* gives: 13 - #1^4 + #1^5 & *)

And then you don't want those silly # characters, but something like x instead:

rootfunction[x] (* gives: 13 - x^4 + x^5 *)

---

I think a possible mistake you made is that you put an extra & after an expression that is already a pure function, i.e.:

rootfunction&[x] (* gives: 13 - #1^4 + #1^5 & *)

The reason for this, perhaps unexpected, behavior is that when you have a nested function like ( #1 & ) & [x] the outer function has no slots (no #s) for the x to fit into. So the x just "disappears" (it's not used in the outer function) and that just leaves the inner function #1& to be returned.