Import a column of data, make a matrix from it and export it WITHOUT curly braces

Question

I'm new here and with Mathematica, too. I want Mathematica to import data from a txt file (it has one column of data). These entries are z-values. From this I want to make a matrix - 508 entries make one row, 308 rows in total. And then I want to export it to a dat file.

Here is my code:

data = Import["D:\\Data\\Mathematica\\Convert_data\\rawdata.txt", "Table"]; Flatten[data];
carray = ConstantArray[1, {308, 508}];
For[j = 1, j < 309, j++, 
  For[i = 1, i < 508, i++, carray[[j, i]] = data[[(j - 1)*508 + i]] ]
];
Export["test.dat", carray, "Table"]

It does nearly everything it is supposed to do. It creates a matrix as I want it to, but all the entries are in curly braces. I think the problem is right at the beginning, when I import the data, all the entries are in a curly brace, and all these braces are within a common brace. I tried to get rid of the single curly braces around each value with "Flatten", but it doesn't do anything.

The txt file I start with looks like this:

1.598669e+000   
1.570571e+000   
1.600274e+000   
1.513271e+000   
1.549999e+000   
1.426268e+000   
1.197772e+000
....

It has many entries, so I don't show all of them here.

Answer 1

Because the data in the text file has one column, importing using the "Table" format produces a nested N × 1 array, where N is the number of lines in the file. Instead, use the "List" import format, and you will get a one-dimensional array:

Import["D:/Data/Mathematica/Convert_data/rawdata.txt", "List"]

should give {1.59867, 1.57057, 1.60027, 1.51327, 1.55, 1.42627, 1.19777, ...}. The rest of your code should then work as expected, except the condition in the For loop over i should be i < 509.

But it's almost always better to use built-in functions, rather than loops. You can use the function Partition to split your list into a nested 308 × 508 array:

Export["test.dat", Partition[Import["D:/Data/Mathematica/Convert_data/rawdata.txt", "List"], 508], "Table"];

---

Here's an example using ImportString and ExportString instead:

ExportString[Partition[ImportString["1.598669e+000
    1.570571e+000
    1.600274e+000
    1.513271e+000
    1.549999e+000
    1.426268e+000
    1.197772e+000
    1.197772e+001", "List"], 4], "Table"]

Answer 2

Try the following:

(* Import your data as tab-separated values; extra "" will be included *)
Import["c:\\Users\\Marco\\Desktop\\Sandbox\\rawdata.txt", "TSV"];
Flatten[%];

(* remove the "" caused by the extra tabs in your data file *)
DeleteCases[%, ""];

(* Reshape your data into an array with your required dimensions *)
ArrayReshape[%, {308, 508}];

(* Export the reshaped array to a *.DAT files *)
Export["data.dat", %]