How to use Compile to generate an $n\times n$ array using $n$ vectors

Question

Let's consider the following:

n = 1000; m=3;
p = RandomReal[{0, 9}, {n,m}];

f = Compile[{{ps, _Real, 2}},
 Outer[
  Which[
   2 < Abs[#1[[1]] - #2[[1]]] < 3 && 2 < Abs[#1[[2]] - #2[[2]]] < 3,
   Sin@Norm[#1 - #2],
   2 < Abs[#1[[2]] - #2[[2]]] < 3 && 2 < Abs[#1[[3]] - #2[[3]]] < 3,
   Cos@Norm[#1 - #2]
  ,True, 0]
 &, ps, ps]];

f[p]

It gives the error message

Compile::part: Part specification Compile`FunctionVariable$41818[1] cannot be compiled since the argument is not a tensor of sufficient rank. Evaluation will use the uncompiled function. >>

because Outer doesn't combine vectors like it does elements (see f.e. Outer[h, {{1, 2}, {3, 4}}, {{5, 6}, {7, 8}}] - the elements are not say h[{1,2},{5,6}] as you might think, which is what I want). How can I solve this? I left the Compile in because it is important to me that the solution is compilable.

The result should be a sparse array of numeric values.

This is basically an extension of my earlier question Faster use of Condition for a large array (see the example) which was answered by Pickett. As the code above shows, I don't know what to do when p is a two-dimensional list instead of a one-dimensional list.

Answer 1

It is true that Outer cannot solve this problem inside Compile. Outside Compile it works to change the head p to something other than List, but Compile doesn't work with general heads. Instead you have to use another function to create the matrix. I suggest:

f = Compile[{{p, _Real, 2}},
  Table[Which[
      2 < Abs[#1[[1]] - #2[[1]]] < 3 && 2 < Abs[#1[[2]] - #2[[2]]] < 3, Sin@Norm[#1 - #2],
      2 < Abs[#1[[2]] - #2[[2]]] < 3 && 2 < Abs[#1[[3]] - #2[[3]]] < 3, Cos@Norm[#1 - #2],
      True, 0] &[x, y], {x, p}, {y, p}]
  ]