How to make a notebook take action whenever a particular symbol is defined or redefined?

Question

For teaching purposes, I want to create a Mathematica notebook that will "notice" when the user defines or redefines a variable or function of a particular name, so that it can check the value and take some appropriate action. For example, the notebook might be monitoring the symbol "foo", so that if the user executes foo = 22/7 at any time, code that I've written and hidden (perhaps in an invisible cell, perhaps via an initialization cell that loads a package I've written) might write out some hint text, e.g. "You've guessed the right variable name, but not the right value yet." I know I could do this by having the user click an explicit "test" button or some such thing, but I'd rather have my code monitor the user invisibly and take action without the user invoking it.

Is this possible? If so, how might it be implemented?

Answer 1

Something, that more or less does what you asked for, can be achieved by creating a hidden InitializationCell using a DynamicWrapper

DynamicWrapper["xxx", 
 If[foo == 23, MessageDialog["You guessed it!"], 
  MessageDialog["You've guessed the right variable name, but not the right value yet."]]]

---

A much more elegant method is to use NotebookDynamicExpression:

SetOptions[EvaluationNotebook[], 
  NotebookDynamicExpression :> 
   Refresh[If[foo == 23, MessageDialog["You guessed it!"], 
     MessageDialog[
      "You've guessed the right variable name, but not the right value yet."]], 
    TrackedSymbols :> {foo}]];

You can remove this cell after evaluating it once, as the NotebookDynamicExpression is now part of the notebook.

---

Yet another possibility is to use ValueFunction in a hidden InitializationCell:

ValueFunction[foo] = 
  If[#2 == 23, MessageDialog["You guessed it!"], 
    MessageDialog[
     "You've guessed the right variable name, but not the right value yet."]] &;

Answer 2

One can use $Pre to check if an input expression defines the correct variable and is doing so using the correct value.

SetAttributes[check, HoldAll]
check[new_Set] := (Print["You guessed it!"]; new) /; HoldForm@new == HoldForm@Set[foo, 23]
check[new_Set] := (Print[
  "You've guessed the right variable name, but not the right value yet."]; new) /; 
 Extract[HoldForm[new], {1, 1}, Hold] == Hold[foo]
check[new_] := new
$Pre = check;