4
$\begingroup$

How can we force Mathematica to compute this limit? $$\lim_{x\to 1} \, \int -\frac{i \text{Li}_2\left(x-x^2\right)}{\sqrt{3} \left(x-\frac{1}{2}-\frac{i \sqrt{3}}{2}\right)} \, dx$$

It seems it works when trying $x\to 0$, but not in the previous case. What possibilities might I have?

This is the command I used 

Limit[
  Integrate[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x))), x], 
  x -> 1]
Improve this question
$\endgroup$
4
  • 1
    $\begingroup$ Does this question make sense mathematically? Since you have an indefinite integral, there's the arbitrary constant to consider. $\lim_{x\to1}\int_1^x f(t)dt = 0$, but $\lim_{x\to1}\int_0^x f(t)dt$ might not. $\endgroup$
    – Greg Hurst
    Commented Nov 11, 2016 at 20:41
  • $\begingroup$ @ChipHurst I think you didn't see the picture behind because it's about calculating $\int_0^1$. $\endgroup$
    – user 1357113
    Commented Nov 11, 2016 at 21:53
  • $\begingroup$ Ah I see, thanks. $\endgroup$
    – Greg Hurst
    Commented Nov 11, 2016 at 23:22
  • $\begingroup$ Actually I also (in line with @ChipHurst) do not see what do you mean by taking the limit of indefinite integral. It is actually an arbitrary number. $\endgroup$
    – yarchik
    Commented Apr 18, 2018 at 21:08

3 Answers 3

Reset to default
8
$\begingroup$

Adding the assumption that x is real (which it is in this case) and then simplifying allows Mathematica to compute a symbolic answer:

$Assumptions = Element[x, Reals];
Integrate[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x))), x];
Simplify @ %;
Limit[%, x -> 1]

On 10.1 these commands yield the following (after some computation time):

1/108 ((8 π^3+9 π Log[(I-Sqrt[3])/(I+Sqrt[3])]^2-72 π Log[(I-Sqrt[3])/(I+Sqrt[3])] Log[(I+Sqrt[3])/(-I+Sqrt[3])]+36 π Log[(I+Sqrt[3])/(-I+Sqrt[3])]^2-36 π PolyLog[2,(-1)^(1/3)]-36 π PolyLog[2,-(-1)^(2/3)]-36 π PolyLog[2,1-(-1)^(1/3)]-72 π PolyLog[2,1+(-1)^(2/3)]+36 π PolyLog[2,(I+Sqrt[3])/(-I+Sqrt[3])])/Sqrt[3]+(1/Sqrt[3])I (-54 Log[1+I Sqrt[3]] Log[(I-Sqrt[3])/(I+Sqrt[3])]^2+54 Log[-I+Sqrt[3]] Log[(I-Sqrt[3])/(I+Sqrt[3])]^2+12 π^2 Log[I+Sqrt[3]]-24 π^2 Log[(I+Sqrt[3])/(-I+Sqrt[3])]+108 Log[I+Sqrt[3]] PolyLog[2,(-1)^(1/3)]+108 Log[I+Sqrt[3]] PolyLog[2,-(-1)^(2/3)]+108 Log[(I-Sqrt[3])/(I+Sqrt[3])] PolyLog[2,1-(-1)^(1/3)]-108 Log[(I-Sqrt[3])/(I+Sqrt[3])] PolyLog[2,(1-I Sqrt[3])/(2 (1+(-1)^(2/3)))]+108 Log[(I-Sqrt[3])/(I+Sqrt[3])] PolyLog[2,(I-Sqrt[3])/(I+Sqrt[3])]-108 Log[(I-Sqrt[3])/(I+Sqrt[3])] PolyLog[2,(I+Sqrt[3])/(-I+Sqrt[3])]+108 PolyLog[3,1-(-1)^(1/3)]+216 PolyLog[3,1+(-1)^(2/3)]+216 PolyLog[3,(1-I Sqrt[3])/(2 (1+(-1)^(2/3)))]-108 PolyLog[3,(I-Sqrt[3])/(I+Sqrt[3])]+108 PolyLog[3,(I+Sqrt[3])/(-I+Sqrt[3])]+324 Zeta[3]))

With FullSimplify this can be reduced to:

(π (26 π^2+36 I π Log[2]+(-5+4 I Sqrt[3]) PolyGamma[1,1/6]+(5-12 I Sqrt[3]) PolyGamma[1,1/3]+(5+12 I Sqrt[3]) PolyGamma[1,2/3]+(-5-4 I Sqrt[3]) PolyGamma[1,5/6])+840 I Zeta[3])/(216 Sqrt[3])

Both results have a numerical value of 1.04978 + 4.17538 I

This value can be independently confirmed with NLimit and without using any assumptions:

Needs["NumericalCalculus`"]
Integrate[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x))), x];
NLimit[%, x -> 1]

1.04978 + 4.17538 I

Note that with NLimit, setting the Direction option to I or -I yields a different limit, the same one that bbgodfrey found:

Needs["NumericalCalculus`"]
Integrate[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x))), x];
NLimit[%, x -> 1, Direction -> I]

3.03883 + 1.54225 I
Improve this answer
$\endgroup$
2
  • $\begingroup$ Many thanks (+1) $\endgroup$
    – user 1357113
    Commented Jun 29, 2015 at 16:16
  • $\begingroup$ And you are Ok with the fact that adding a constant to the integral is still the same indefinite integral? $\endgroup$
    – yarchik
    Commented Apr 18, 2018 at 21:10
6
$\begingroup$

The idea is to let x = 1 + eps, expand the integral (antiderivative) into a series with respect to eps, and then let eps -> 0.

Mathematica 10.1 quickly returns the result to which some "beautifying" was done afterwards by hand.

Here's the code

FullSimplify[
 Limit[Series[
     Integrate[-((I PolyLog[2, x - x^2])/(Sqrt[
             3] (-(1/2) - (I Sqrt[3])/2 + x))), x] /. 
      x -> 1 + \[Epsilon], {\[Epsilon], 0, 0}, 
     Assumptions -> \[Epsilon] > 0] // Normal // 
   Simplify, \[Epsilon] -> 0]]

(*
(\[Pi] (26 \[Pi]^2 + 
    36 I \[Pi] Log[2] + (-5 + 4 I Sqrt[3]) PolyGamma[1, 1/
      6] + (5 - 12 I Sqrt[3]) PolyGamma[1, 1/
      3] + (5 + 12 I Sqrt[3]) PolyGamma[1, 2/
      3] + (-5 - 4 I Sqrt[3]) PolyGamma[1, 5/6]) + 
 840 I Zeta[3])/(216 Sqrt[3])
*)

%//N

(* 1.04978 + 4.17538 I *)

This conincides with Nick's solution.

Improve this answer
$\endgroup$
1
  • $\begingroup$ Many thanks (+1) $\endgroup$
    – user 1357113
    Commented Jun 29, 2015 at 16:16
5
$\begingroup$

Edit: material reordered for clarity

The formal definition of the PolyLogorithm is Sum[z^k/k^n, {n, 1, Infinity}], which converges for Abs[z] < 1. Thus, the integrand can be integrated term-wise.

summand = Integrate[-I (x (1 - x))^k/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x)), x]
     // FullSimplify
(* ((-1)^(1/6) x^(1 + k) AppellF1[1 + k, -k, 1, 2 + k, x, -(-1)^(2/3) x])/
   (Sqrt[3] (1 + k)) *)

The value of summand at x = 1 is

summand /. x -> 1
(* ((-1)^(1/6) 2^(-1 - 2 k) Sqrt[\[Pi]/3] Gamma[2 + k] 
   Hypergeometric2F1[1, 1 + k, 2 + 2 k, -(-1)^(2/3)])/((1 + k) Gamma[3/2 + k]) *)

Of course, summand /. x -> 0 is 0. The first ten terms of the series are adequate to give a good answer.

Sum[(summand /. x -> 1) k^-2, {k, 1, 10}] // N // Chop
(* 0.110503 *)

This same result can be obtained by numerically integrating the integrand from x = 0 to x = 1.

NIntegrate[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x))), {x, 0, 1}] 
    // Chop
(* 0.110503 *)

For completeness, note that the integrand is well behaved throughout the range of integration. 

Plot[Evaluate[
  ReIm[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x)))]], {x, 0, 1}]

enter image description here

(The Real and Imaginary parts are blue and orange, respectively.)

However, it is important to remember that the anti-derivative of any function is determined only up to an arbitrary constant. Thus,

int = Integrate[-((I PolyLog[2, x - x^2])/(Sqrt[3] (-(1/2) - (I Sqrt[3])/2 + x))), x];
int /. x -> .9999
(* 3.03883 + 1.54225 I*)

gives a different answer, because Integrate has thrown in a different constant in this case. Varying x shows that this numerical solution has converged.

(int /. x -> .99999) - (int /. x -> .9999)
(* 2.47505*10^-9 - 1.42876*10^-9 I *)

Which result is preferable depends on how the OP plans to use it.

Improve this answer
$\endgroup$
2
  • $\begingroup$ Many thanks (+1) $\endgroup$
    – user 1357113
    Commented Jun 29, 2015 at 16:16
  • $\begingroup$ @Chris'ssistheartist Please note the cautionary statement at the end of my Answer. I recommend that you add to your question how you plan to use the result, which may impact how it should be derived. $\endgroup$
    – bbgodfrey
    Commented Jun 29, 2015 at 16:42

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.