# Plotting two parametric regions together

I have the following code below, which allows me to plot two nice figures in the plane.

z = a + I*b;
f[z_] = 1 + z + z^2/2 + z^3/6 + z^4/24 ;
g[z_] = z + 1;
ParametricPlot[{a, b}, {a, -3, 1}, {b, -3, 3},
RegionFunction -> Function[{a, b}, Abs[f[z]] < 1], MaxRecursion -> 4]
ParametricPlot[{a, b}, {a, -3, 1}, {b, -3, 3},
RegionFunction -> Function[{a, b}, Abs[g[z]] < 1], MaxRecursion -> 6]


In order to put them together, I came up with the following.

z = a + I*b;
f[z_] = 1 + z + z^2/2 + z^3/6 + z^4/24 ;
g[z_] = z + 1;
ParametricPlot[{ConditionalExpression[{a, b}, Abs[f[z]] < 1],
ConditionalExpression[{a, b}, Abs[g[z]] < 1]}, {a, -3, 1}, {b, -3, 3}]


Now I got this terrible figure. Even setting MaxRecursion to it's maximum won't make difference. How can I solve this problem?

Thanks.

• Why not use RegionFunction again? Function[{a, b}, Abs[f[z]] < 1 || Abs[g[z]] < 1]? (Use && if you want the intersection instead of the union.) – J. M. is away Jun 24 '15 at 2:53
• You mean inside or outside the conditional expression? Outside I'm not sure I want and inside I'm not sure how it works. – Integral Jun 24 '15 at 2:54
• Hmmmm... I think I got what you mean, let me give a try. – Integral Jun 24 '15 at 2:56
• Ah, if you want the two regions to be distinct, then just put them in separate ParametricPlot[]s and use Show[] to combine them. – J. M. is away Jun 24 '15 at 3:01
• Then, can you please write an answer to your own question? – J. M. is away Jun 24 '15 at 3:17

The code below solved my problem.

z = a + I*b;
f[z_] = 1 + z + z^2/2 + z^3/6 + z^4/24 ;
g[z_] = z + 1;
P1 := ParametricPlot[{a, b}, {a, -3, 1}, {b, -3, 3},
RegionFunction -> Function[{a, b}, Abs[f[z]] < 1],
MaxRecursion -> 4];
P2 := ParametricPlot[{a, b}, {a, -3, 1}, {b, -3, 3},
RegionFunction -> Function[{a, b}, Abs[g[z]] < 1],
MaxRecursion -> 4];
Show[P1, P2]


I got the following figure.

I was thinking about two different colors, but this two kinds of blue are just fine. Of course changing the colors are not a problem now, if I want to change. Thank you for the help, Guess who it is.

I have upvoted the self answer. Just to illustrate another approach:

f[z_] := 1 + z + z^2/2 + z^3/6 + z^4/24;
g[z_] := z + 1
RegionPlot[{Abs[f[x + I y]] < 1, Abs[g[x + I y]] < 1}, {x, -3,
1}, {y, -3, 3}, PlotStyle -> {Red, Blue}, AspectRatio -> Automatic]