Dynamic does not update when wrapped in DynamicModule

Question

I'm trying to wrap some dynamic code into DynamicModule to localize all the variables, yet when I do that, the variables stop updating.

That does not happen if I use Module instead. However, the variables get highlighted in red and when I hover over them with the mouse pointer the following message pops up: "A variable was used where it is probably not going to be evaluated before going out of scope".

The code in question is from Pickett's answer to my earlier question (AJAX-style HTTP calls triggered by a variable change):

url = "https://maps.googleapis.com/maps/api/geocode/json";
callback[_, "data", data_] := choices = extractsAddresses@First@FromCharacterCode[data]

Needs["GeneralUtilities`"]
extractsAddresses[data_] := ToAssociations[ImportString[data, "JSON"]][["results", All, "formatted_address"]]

fetchChoices[addr_] := URLFetchAsynchronous[
  url,
  callback,
  "Parameters" -> {"address" -> addr}
  ]

Column[{
  InputField[
   Dynamic[s, (fetchChoices[#]; s = #) &],
   String,
   ContinuousAction -> True
   ],
  Dynamic@choices
  }]

And here is the version wrapped in DynamicModule:

Needs["GeneralUtilities`"]
DynamicModule[{url, callback, choices = "", fetchChoices, s},
 url = "https://maps.googleapis.com/maps/api/geocode/json";
 callback[_, "data", data_] := 
  choices = extractsAddresses@First@FromCharacterCode[data];
 extractsAddresses[data_] := 
  ToAssociations[ImportString[data, "JSON"]][["results", All, 
    "formatted_address"]];
 fetchChoices[addr_] := 
  URLFetchAsynchronous[url, callback, 
   "Parameters" -> {"address" -> addr}];
 Column[{InputField[Dynamic[s, (fetchChoices[#]; s = #) &], String, 
    ContinuousAction -> True], Dynamic@choices}]
 ]

What am I doing wrong?

Answer 1

I think you are actually not doing anything wrong but have found one of those cases where the automatic dependency tracking doesn't work (I think this is a bug and is also discussed in other questions, e.g. here, here or here). You can make the code work (version 10.1 on Windows) by explicitly telling the last Dynamic to track choices:

 Dynamic[choices,TrackedSymbols:>{choices}]

There are some things in your code that I probably would solve different (e.g. url is a constant and it is also unusual to localize function names like callback and fetchChoices as DynamicModule variables, also your function definitions would probably be better put into the Initialization option of DynamicModule). Here is a version which should work using the usual conventions:

Needs["GeneralUtilities`"];
With[{url="https://maps.googleapis.com/maps/api/geocode/json"},
    DynamicModule[{choices="",string},
        Column[{
            InputField[
                Dynamic[string,(fetchChoices[#];string=#)&],
                String,ContinuousAction->True
            ],
            Dynamic[choices,TrackedSymbols:>{choices}]
        }],

        Initialization:>(
            Needs["GeneralUtilities`"];
            callback[_,"data",data_]:=(
                choices=extractAddresses@First@FromCharacterCode[data]
            );
            extractAddresses[data_]:=ToAssociations[
                ImportString[data,"JSON"]
            ][["results",All,"formatted_address"]];
            fetchChoices[addr_]:=URLFetchAsynchronous[
                url,callback,"Parameters"->{"address"->addr}
            ];
        )
    ]
]

when playing with this you will find that sometimes the shown choices seem to not match the current string. I think that is because it is not guaranteed that the asynchronous callbacks will return in the order in which they are issued. You might need to handle that for a real application, e.g. only update choices when the received value is from a later call then the currently shown...