How can I check that the general solution obeys the original differential equation?

Question

For example: I solved the following differential equation:

y''[x] == (λ x^(3/4) y[x])/Sqrt[1-x]

that 0<x<1 with the following method:

sol = DSolve[z''[x] == λ*x^(3/4)* z[x]/Sqrt[x], z[x], x]
y[x_] = z[x] /. sol[[1]] /. x -> x - 1

and obtained this general solution:

(2/3)^(8/9) Sqrt[-1 + x] λ^(2/9)
   BesselI[-(4/9), 8/9 (-1 + x)^(9/8) Sqrt[λ]] C[1] Gamma[5/
   9] + (-1)^(4/9) (2/3)^(8/9) Sqrt[-1 + x] λ^(2/9)
   BesselI[4/9, 8/9 (-1 + x)^(9/8) Sqrt[λ]] C[2] Gamma[13/9]

How can I check that the general solution obeys the original differential equation ?

Answer 1

You can check that a differential equation is solved correctly by plugging it in to the original equation and seeing that it holds. For your case:

sol = DSolve[z''[x] == λ*x^(3/4)*z[x]/Sqrt[x], z[x], x]
f[x_] := sol[[1, 1, 2]]

so f[x] is the candidate function. Now verify that:

FullSimplify[D[f[x], {x, 2}]] == FullSimplify[λ*x^(3/4)*f[x]/Sqrt[x]]

Since this returns True, you know you have the right answer.

Answer 2

In this example, the solution is verified by substitution.

equation = y''[x]-x*y[x]-x == 0;
sol = DSolve[equation, y, x]
FullSimplify[equation /. sol]

{ True }

You can also check numerically. An example, we have a differential equation:

$$y''(x)-x y(x)-x=0$$

General solution is:

$$\left\{y(x)\to c_1 \text{Ai}(x)+c_2 \text{Bi}(x)-\pi \text{Ai}(x) \text{Bi}'(x)+\pi \text{Ai}'(x) \text{Bi}(x)\right\}$$

On the right side of the differential equation we have zero , so:

 sol = First@DSolve[y''[x] - x*y[x] - x == 0, y[x], x]
 Y = y[x] /. sol;
 DE = D[Y, {x, 2}] - x*Y - x;
 N@Table[DE /. {C[1] -> a, C[2] -> b, x -> c},
 {a, 1, 3}, {b, 1, 3}, {c, 1, 3}] // MatrixForm

Almost here are zeros.Check OK.