# Problems with finding the real solutions of equation

I am trying to find real solutions of equation using Mathematica 8.0 but there is some problem I don't know how to explain.

For example, for the input

Solve[x^16 + x^3 + x + 1 == 0, x, Reals]


it gives

{{x -> -1}, {x -> Root[1 + #1 - #1^4 + #1^7 - #1^10 + #1^13 &, 1]}}


What does this mean?

• Thanx to all for very detailed answers! – user2000000 Jun 24 '15 at 17:29

## 3 Answers

eqn = x^16 + x^3 + x + 1 == 0;

sol = Solve[eqn, x, Reals]


{{x -> -1}, {x -> Root[1 + #1 - #1^4 + #1^7 - #1^10 + #1^13 & , 1]}}

Verifying the solution

eqn /. sol // Simplify


{True, True}

Root[f, k]represents the exact k^th root of the polynomial equation f[x]==0. Read the documentation for Root. The exact representation can be converted to an approximate real value using N

sol // N


{{x -> -1.}, {x -> -0.683269}}

Verifying the approximate solution

eqn /. %


{True, True}

or to keep the integer solution as an integer

sol /. y_Root :> N[y]


{{x -> -1}, {x -> -0.683269}}

• Does ToRadicals[] do anything productive on the Root[] expression? – J. M. will be back soon Jun 17 '15 at 22:50
• @Guesswhoitis. the order of this polynomial (order 13) is too high for ToRadicals to be able to convert the expression to the alternate representation. For much lower order polynomials it can be useful to those that prefer radical representations over the equivalent Root representations. – Bob Hanlon Jun 17 '15 at 22:55

According to Mathematica Documentation, Root[f,k] gives the $k^{th}$ root of the polynomial function f[x]==0. Try to see if you get the numerical values with the following:

sol=Solve[x^16+x^3+x+1==0,x,Reals]
N[sol]


To see why this happened, we can firstly factor the polynomial in $\mathbb{Q}$.

Factor[x^16 + x^3 + x + 1]

(1 + x) (1 - x + x^2) (1 + x - x^4 + x^7 - x^10 + x^13)


So -1 is a real root. The roots of 1 - x + x^2 are complex, now we consider the last polynomial. We need The Fundamental Theorem of Algebra:

Every $f\in\mathbb{R}[x]$ of odd degree has at least one root in $\mathbb{R}.$

The function CountRoots can give the number of real roots of a polynomial.

CountRoots[1 + x - x^4 + x^7 - x^10 + x^13, x]

1


The origin polynomial has two real roots, i.e. one is -1, the other is the real root of 1 + x - x^4 + x^7 - x^10 + x^13. But because of the Galois Theory the polynomial of degree greater than 4 is not solvable by radical. In Mathematica the roots of a polynomial with degree $>4$ are usually expressed as Root[poly,k]. You can easily verify that when k=1 the root is real.