Asymptotics of $\frac{\sum _{i=0}^{\lfloor n/2 \rfloor} {2(n-2i) \choose n-2i} {n \choose 2i} {4i \choose 2i}}{2^{3n - 1}}$

Question

I am fairly sure that asymptotically $$\frac{\sum _{i=0}^{\lfloor n/2 \rfloor} {2(n-2i) \choose n-2i} {n \choose 2i} {4i \choose 2i}}{2^{3n - 1}} \sim \frac{2}{\pi n}.$$

I tried

Limit[n*Sum[Binomial[2n-4i,n-2i]*Binomial[n,2i]*Binomial[4i,2i],{i,0,n/2}]/2^(3n-1), n-> Infinity]

but Mathematica can't compute it.

Is there another way to persuade Mathematica to do this sort of asymptotics?

In Find asymptotics of $\sum\limits_{i=0}^{n/3} 2^i \binom{n-i-1}{\frac{2n}{3}-1}$ there is a clever use of Normal@Series as well as some other ideas for getting asymptotics but I didn't manage to get them to work for this problem.

Answer 1

For n even, the Sum in the question can be performed explicitly,

Evaluate[Unevaluated[n*Sum[Binomial[2 n - 4 i, n - 2 i]*Binomial[n, 2 i]*
         Binomial[4 i, 2 i], {i, 0, Floor[n/2]}]/2^(3 n - 1)] /. 
         n -> 2 m /. Floor[(2*m)/2] -> m] // Simplify
(* 4^(1 - 3 m) m Binomial[4 m, 2 m] HypergeometricPFQ[
         {1/4, 3/4, 1/2 - m, 1/2 - m, -m, -m}, {1/2, 1/2, 1, 1/4 - m, 3/4 - m}, 1] *)

and then partially expanded

f65 = Simplify[Series[%, {m, Infinity, 0}] // Normal, m > 0 && m ∈ Integers]
(* (2^(3/2 - 2 m) Sqrt[m] HypergeometricPFQ[{1/4, 3/4, 1/2 - m, 1/2 - m, -m, -m}, 
         {1/2, 1/2, 1, 1/4 - m, 3/4 - m}, 1])/Sqrt[π] *}

(A similar calculation can, of course, be obtained for n odd.) Next, f65 is represented as a series of Pochhammer symbols.

2^(3/2 - 2 m) Sqrt[m/π] Sum[
  Pochhammer[1/4, k] Pochhammer[3/4, k] Pochhammer[-m, k]^2 Pochhammer[1/2 - m, k]^2/
  (Pochhammer[1/2, k]^2 Pochhammer[1, k] Pochhammer[1/4 - m, k] Pochhammer[3/4 - m, k])/k!
  , {k, 0, ∞}]

Large m expansions of the sort described in 32950 only work for ratios of equal numbers of Pochhammer symbols involving m. So, expand just the ratio of the last two Pochhammer symbols in the numerator and denominator.

Series[Pochhammer[1/2 - m, k]^2/(Pochhammer[1/4 - m, k] Pochhammer[3/4 - m, k]), {m, ∞, 1}]
   // Normal // FullSimplify[#, k ∈ Integers] &
(* (E^((1/96)/m) (-1 + 96 m))/(96 m) *)
Limit[%, m -> ∞]
(* 1 *)

Hence, in this limit f65 reduces to

f43 = 2^(3/2 - 2 m) Sqrt[m/π] Sum[
  Pochhammer[1/4, k] Pochhammer[3/4, k] Pochhammer[-m, k]^2/
  (Pochhammer[1/2, k]^2 Pochhammer[1, k])/k!
  , {k, 0, ∞}]
(* (2^(3/2 - 2 m) Sqrt[m/π] HypergeometricPFQ[{1/4, 3/4, -m, -m}, {1/2, 1/2, 1}, 1] *)

At this point it is, perhaps, worth noting that

f43 /. m -> 100000 // N[#, 10] &
(* 0.6366197724 *)

still is equal to 2/π to 10 significant figures. Interestingly, the terms in the f43 Sum can be further simplified by

t43s = FullSimplify[2^(3/2 - 2 m) Sqrt[m/π] Pochhammer[1/4, k] Pochhammer[3/4, k] 
          Pochhammer[-m, k]^2/(Pochhammer[1/2, k]^2 Pochhammer[1, k])/k!,
          k ∈ Integers && m ∈ Integers]
(* (2^(3/2 + 2 k - 2 m) Sqrt[m]
      Gamma[1/2 + 2 k] Pochhammer[-m, k]^2)/(π Gamma[1 + 2 k]^2) *)

but summing over t43s just returns f43. I know of no exact simplifications of f43 in the large m limit, although one may exist.

Because Pochhammer[-m, k] vanishes for k > m and m a positive integer, it is possible to evaluate and plot every non-vanishing t43s. For instance,

ListPlot[Table[t43s /. m -> 1000, {k, 0, 1000}], DataRange -> 1, PlotRange -> All]

A quite good fit to this curve is given by

4/π^(3/2) m^(-1/2) Exp[-4 m ((k - m/2)/m)^2]`

The coefficient 4/π^(3/2) m^(-1/2) can be obtained from

Assuming[m > 0 && m ∈ Integers, Series[(2^(3/2 + 2 k - 2 m) Sqrt[m] Gamma[1/2 + 2 k] 
  Pochhammer[-m, k]^2)/(π Gamma[1 + 2 k]^2) /. k -> m/2, {m, ∞, 0}]] // Normal

for even m. An expansion of t43s about k = m/2 then gives the width 2/Sqrt[m]. The resulting agreement is very good, as can be seen from

With[{m = 1000}, ListLogPlot[{Table[(2^(3/2 + 2 k - 2 m) Sqrt[m]
        Gamma[1/2 + 2 k] Pochhammer[-m, k]^2)/(π Gamma[1 + 2 k]^2), {k, 0, m}], 
        Table[(2 m)^-(1/2) Exp[-4 m ((k - m/2)/m)^2], {k, 0, m}]}, 
        DataRange -> 1, PlotRange -> All]]

(t43s is blue, the fitted function orange.) The fitted function can be integrated to give

Assuming[ m > 0, Integrate[4/π^(3/2) m^(-1/2) Exp[-4 m ((k - m/2)/m)^2], {k, -∞, ∞}]]
(* 2/π *)

as desired.

Addendum: Improved Proof Based on Pochhammer Substitution

The barrier to expanding f43 is Pochhammer[-m, k], which is not continuous for positive integer m and k. However, even though Mathematica appears not to know it,

Assuming[m >= k >= 0 && (m | k) ∈ Integers, 
  Pochhammer[-m, k]^2 == Pochhammer[m + 1 - k, k]^2]

is True, as can be seen empirically by trying numerous values of m and k. Furthermore, making this substitution into the expression above for f43 gives the same result as before. So, let us focus on the alternative representation,

t43a = (2^(3/2 - 2 m) Sqrt[m] Pochhammer[1/4, k] Pochhammer[3/4, k] 
  Pochhammer[m + 1 - k, k]^2)/(Sqrt[π] k! Pochhammer[1/2, k]^2 Pochhammer[1, k])

Because it is apparent from the first plot above that t43a is large only near k = m/2, t43a should be expanded for large m with k = a m.

(Assuming[0 < a < 1, Series[t43a /. k -> a m, {m, ∞, 1}]] //
    Normal) // FullSimplify[#, m > 0] &
(* (4^-m (1 - a)^(-1 + 2 (-1 + a) m) a^(-1 - 2 a m))/(Sqrt[m] π^(3/2)) *)
Exp[(Series[Log[%], {a, 1/2, 2}] // Normal) /. a -> k/m]
(* (4 E^((-(1/2) + k/m)^2 (4 - 4 m)))/(Sqrt[m] π^(3/2)) *)
Limit[Integrate[%, {k, -∞, ∞}, Assumptions -> m > 1], m -> ∞]
(* 2/π *)

which provides a superior derivation, one not involving curve-fitting.

Answer 2

Clear[expr]

expr[n_Integer] := 
  n*Sum[Binomial[2 n - 4 i, n - 2 i]*Binomial[n, 2 i]*
      Binomial[4 i, 2 i], {i, 0, Floor[n/2]}]/2^(3 n - 1);

expr2 = expr[10000] // N

0.63662

RootApproximant[expr2*Pi]/Pi

2/Pi