7
$\begingroup$

I am running Mathematica 7 on Windows XP Pro. I often use the magnification feature to zoom in on Plots, ListPlots, and Graphics that I have created. If I go to the Window menu, there is a Magnification option, which gives a submenu with the following options:

  • 50%
  • 100%
  • 125%
  • 150%
  • 200%
  • 300%

Is it possible to use a magnification of, for example, 110%?

$\endgroup$
  • $\begingroup$ Andrew, I am editing your question to make it version-independent. I don't think this should be a problem as you already received a solution but let me know if it is. $\endgroup$ – Mr.Wizard Aug 17 '14 at 17:33
  • $\begingroup$ People may want to know that the default Magnification option for $FrontEnd is 1 and for EvaluationNotebook[] it is Inherited. If you zoom using the menu at the bottom, this changes the EvaluationNotebook[]'s Magnification option to say 1.25 Inherited. $\endgroup$ – masterxilo Apr 2 '17 at 12:26
9
$\begingroup$

Something like this might help:

SetOptions[EvaluationNotebook[],DockedCells->
Cell[BoxData[ToBoxes[DynamicModule[{m=1},Panel[Slider[
Dynamic[m,SetOptions[EvaluationNotebook[],Magnification->(m=#)]&],{0.5,2.0}],
"Magnification"]]]],"DockedCell"]]

It puts a magnification control into a docked cell at the top of the notebook window.

$\endgroup$
7
$\begingroup$

You cannot directly do that from the Window > Zoom menu option. However, you can use the following to zoom selections at other magnification levels. The following code creates a palette that lets you magnify a selection in your notebook between 50% to 300% in steps of 10.

DynamicModule[{zoom = 1},
    CreatePalette[Column@{
    "Custom zoom",
    Dynamic@Row[{
        Button["-", zoom -= 0.1, Enabled -> (zoom >= 0.5)], 
        100 zoom, 
        Button["+", zoom += 0.1, Enabled -> (zoom <= 3)]
    }],
    Dynamic@Button["Zoom selection", 
        SetOptions[NotebookSelection[SelectedNotebook[]], Magnification -> zoom]]
    }]
]

Evaluating the above code creates a palette like the following:

enter image description here

Now just select anything in your notebook, use the +/- buttons to increase/decrease the magnification and click the button. Here's an example where I've zoom parts of the above code in my notebook:

enter image description here

$\endgroup$
  • $\begingroup$ my eyes! ... :) $\endgroup$ – Dr. belisarius Jul 21 '12 at 22:09
6
$\begingroup$

Since you reference the Window > Magnification menu I think you are describing zoom for the entire Notebook.

You can set magnification in 10% increments by holding Ctrl and rolling the mouse wheel up or down.

By first setting the Magnification to 125% you get 115%, 135% etc, and you can therefore select magnification down to 5% granularity very quickly.


Other magnification values can be set using the Option Inspector or SetOptions. You can for example zoom all Notebooks at once (which do not have Magnification values set internally) with:

SetOptions[$FrontEndSession, Magnification -> 1.17]
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.