Now that the nature of integral has been clarified: $\iint_{D} |x| \mathrm dx\mathrm dy$ where $D$ is region $x^2+y^2<a^2$:
There are a number of ways to evaluate integral:
Integrate[Abs[x], {x, y} \[Element] Disk[{0, 0}, a],
Assumptions -> a > 0]
(*Jacobian to conversion to polar coordinates*)
j = Simplify[Det[Outer[D[#1, #2] &, {r Cos[t], r Sin[t]}, {r, t}]]];
Integrate[Abs[r Cos[t]] j, {r, 0, a}, {t, 0, 2 Pi},
Assumptions -> a > 0]
(*using implicitly defined region*)
reg = ImplicitRegion[
0 < z < Abs[x] &&
x^2 + y^2 < a^2, {{x, -a, a}, {y, -a, a}, {z, 0, a}}];
Assuming[a > 0, Volume[reg]]
All yield (4 a^3)/3
Visualization:
p1 = Plot3D[Abs[x], {x, -1, 1}, {y, -1, 1},
RegionFunction -> Function[{x, y}, x^2 + y^2 < 1], Mesh -> False];
p2 = ParametricPlot3D[{r Cos[t], r Sin[t], Abs[r Cos[t]]}, {r, 0,
1}, {t, 0, 2 Pi}, Mesh -> False];
p3 = RegionPlot3D[reg /. a -> 1, PlotPoints -> 100, Axes -> False,
Boxed -> False, Background -> Black];
Column[{p1, p2, p3}]

(23563)
. Plus it contains a beautiful plot $\endgroup$ – Sektor Jun 5 '15 at 8:16reg=ImplicitRegion[x^2 + y^2 <= a^2, {x,y}]; Integrate[Abs[x],Element[{x,y},reg]](*linebreak here*) Plot3D[Abs[x],{x,-3,3},{y,-3,3},RegionFunction->(Element[{#1,#2},reg/.a->3]&)]
$\endgroup$ – LLlAMnYP Jun 5 '15 at 10:55