Solving a time-dependent structural mechanics problem with Finite Element

Question

I'm trying to solve a time-dependent structural mechanics problem with Finite Element. I modified one of the last samples in the "Solving Partial Differential Equations with Finite Elements" Tutorial.

The following equations should ideally represents a beam initially at rest and then stimulated by a sinusoidal force per unit volume directed ad the $y$ axis.

Needs["NDSolve`FEM`"]

\[CapitalOmega] = Rectangle[{0, 0}, {5, 1}];
mesh = ToElementMesh[\[CapitalOmega]];
mesh["Wireframe"];

op = {Inactive[
       Div][({{0, -((Y \[Nu])/(1 - \[Nu]^2))}, {-((Y (1 - \[Nu]))/(
           2 (1 - \[Nu]^2))), 0}}.Inactive[Grad][
         v[x, y, t], {x, y}]), {x, y}] + 
     Inactive[
       Div][({{-(Y/(1 - \[Nu]^2)), 
          0}, {0, -((Y (1 - \[Nu]))/(2 (1 - \[Nu]^2)))}}.Inactive[
          Grad][u[x, y, t], {x, y}]), {x, y}], 
    Inactive[
       Div][({{0, -((Y (1 - \[Nu]))/(2 (1 - \[Nu]^2)))}, {-((
           Y \[Nu])/(1 - \[Nu]^2)), 0}}.Inactive[Grad][
         u[x, y, t], {x, y}]), {x, y}] + 
     Inactive[
       Div][({{-((Y (1 - \[Nu]))/(2 (1 - \[Nu]^2))), 
          0}, {0, -(Y/(1 - \[Nu]^2))}}.Inactive[Grad][
         v[x, y, t], {x, y}]), {x, y}]} /. {Y -> 10^3, \[Nu] -> 
     33/100};

Subscript[\[CapitalGamma], D] = 
  DirichletCondition[{u[x, y, t] == 0., v[x, y, t] == 0.}, x == 0];
ic = {
   u[x, y, 0] == 0, v[x, y, 0] == 0,
   Derivative[0, 0, 1][u][x, y, 0] == 0, 
   Derivative[0, 0, 1][v][x, y, 0] == 0
   };

{uif, vif} = 
  NDSolveValue[{op == {0, Sin[t]}, Subscript[\[CapitalGamma], D], 
    ic}, {u, v}, {x, y} \[Element] mesh, {t, 0, 2 \[Pi]}, 
   Method -> {"PDEDiscretization" -> {"MethodOfLines", 
       "TemporalVariable" -> t, 
       "SpatialDiscretization" -> {"FiniteElement"}}}];

My real problem is different and more complex but the result is the same

NDSolveValue::tvic: t cannot be used as the temporal independent variable because the conditions {u[x,y,0]==0,v[x,y,0]==0,(u^(0,0,1))[x,y,0]==0,(v^(0,0,1))[x,y,0]==0} for that dimension do not constitute sufficient initial conditions given at only one value of t. >>

NDSolveValue::ivone: Boundary values may only be specified for one independent variable. Initial values may only be specified at one value of the other independent variable. >>

I tried different forms of the force (also op == {0,0} which should end with the stationary solution) and also adding $t>0$ ad a predicate under DirichletCondition without success.

Answer 1

This works:

Needs["NDSolve`FEM`"]

\[CapitalOmega] = Rectangle[{0, 0}, {5, 1}];
mesh = ToElementMesh[\[CapitalOmega]];
mesh["Wireframe"];

op = {Inactive[
       Div][({{0, -((Y \[Nu])/(1 - \[Nu]^2))}, {-((Y (1 - \[Nu]))/(2 \
(1 - \[Nu]^2))), 0}}.Inactive[Grad][v[t, x, y], {x, y}]), {x, y}] + 
     Inactive[
       Div][({{-(Y/(1 - \[Nu]^2)), 
          0}, {0, -((Y (1 - \[Nu]))/(2 (1 - \[Nu]^2)))}}.Inactive[
          Grad][u[t, x, y], {x, y}]), {x, y}], 
    Inactive[
       Div][({{0, -((Y (1 - \[Nu]))/(2 (1 - \[Nu]^2)))}, {-((Y \
\[Nu])/(1 - \[Nu]^2)), 0}}.Inactive[Grad][u[t, x, y], {x, y}]), {x, 
       y}] + Inactive[
       Div][({{-((Y (1 - \[Nu]))/(2 (1 - \[Nu]^2))), 
          0}, {0, -(Y/(1 - \[Nu]^2))}}.Inactive[Grad][
         v[t, x, y], {x, y}]), {x, y}]} /. {Y -> 10^3, \[Nu] -> 
     33/100};

Subscript[\[CapitalGamma], D] = 
  DirichletCondition[{u[t, x, y] == 0., v[t, x, y] == 0.}, x == 0];
ic = {u[0, x, y] == 0, v[0, x, y] == 0};

{uif, vif} = 
 NDSolveValue[{D[{u[t, x, y], v[t, x, y]}, t] + op == {0, Sin[t]}, 
   Subscript[\[CapitalGamma], D], ic}, {u, v}, {t, 0, 
   2 \[Pi]}, {x, y} \[Element] mesh, 
  Method -> {"PDEDiscretization" -> {"MethodOfLines", 
      "TemporalVariable" -> t, 
      "SpatialDiscretization" -> {"FiniteElement"}}}]

You only need to specify derivatives of the initial condition up to degree one less then the time derivative - zero in this case. (For a wave equation, you'd specify the first derivative of the initial condition)