Add text or descriptions to Plot

Question

I would like to add some descriptions or qualifications to Plot as follows: Those in black are what I would like to add to my Plot (this graph is manually created from MS words).

Would PlotStyle be helpful for this?

Answer 1

I use the sine curve to replace your original graph.You can accomplish your graph according to this toy code.

Plot[Sin[x], {x, 0, 2 Pi},
 Epilog ->
  {Red, Thick,
   Line[{{0, 0}, {0, -.2}}],
   Line[{{Pi, 0}, {Pi, -.2}}],
   Line[{{2 Pi, 0}, {2 Pi, -.2}}],
   Black, Arrowheads[{-.04, .04}],
   Arrow[{{0, -.15}, {Pi, -.15}}], Arrow[{{Pi, -.15}, {2 Pi, -.15}}], 
   Text[Style["0<a<1", 13, FontFamily -> Times], {1.5, -.5}], 
   Text[Style["0<b<1", 13, FontFamily -> Times], {1.5, -.7}],
   Text[Style["a>1", 13, FontFamily -> Times], {4.5, -.5}],
   Text[Style["b>1", 13, FontFamily -> Times], {4.5, -.7}]}
 ]

Or you can replace the following code fragment

Text[Style["0<a<1", 13, FontFamily -> Times], {1.5, -.5}], 
Text[Style["0<b<1", 13, FontFamily -> Times], {1.5, -.7}],
Text[Style["a>1", 13, FontFamily -> Times], {4.5, -.5}],
Text[Style["b>1", 13, FontFamily -> Times], {4.5, -.7}]

with

Sequence @@
 (Text[Style[#1, 13, FontFamily -> Times], #2] & @@@ 
  {{"0<a<1", {1.5, -.5}}, {"0<b<1", {1.5, -.7}},
   {"a>1", {4.5, -.5}}, {"b>1", {4.5, -.7}}})