Using PlotLegends->“Expressions” inside Manipulate or DynamicModule doesn't work

Question

Take this simple example:

Manipulate[
 RegionPlot[
  {x^2 + y^2 <= c,
   x < 0},
  {x, -Pi, Pi},
  {y, -Pi, Pi},
  PlotLegends -> "Expressions"
  ],
 {{c, 3.}, 0., 10., 0.1}
 ]

As you can see (unless it's just me of course) the legend text does not display correctly. In particular the value of c is not substituted correctly when the legend text is evaluated.

Doing some research I found that Manipulate basically works like a DynamicModule, and indeed the following breaks in a very similar way, and I guess for the same reasons:

DynamicModule[{c = 3},
 RegionPlot[
  {x^2 + y^2 <= c,
   x < 0},
  {x, -Pi, Pi},
  {y, -Pi, Pi},
  PlotLegends -> "Expressions"
  ]
 ]

while using for example With instead of DynamicModule works correctly.

I could probably fix this by manually inserting the legend with something like

PlotLegends->"x^2+y^2<="<>c

but then I would have to manually tweak the font and all that.

Why does this happen? And what is the correct way to deal with it?

Answer 1

This happens because legend items are wrapped in HoldForm to prevent the elements from taking on values: Observe:

c = 5;

RegionPlot[{x^2 + y^2 <= c, x < 0}, {x, -Pi, Pi}, {y, -Pi, Pi}, 
   PlotLegends -> "Expressions"][[2, 1, 2]] // InputForm

{HoldForm[x^2 + y^2 <= c], HoldForm[x < 0]}

Without the HoldForm any global values (such as c = 5) would be substituted. Most of the time that would be a bad thing.

To get the behavior you want you just need to replace c within the RegionPlot before it is evaluated. This is the same problem as Function in Table and the same methods can be used, e.g. the Accepted answer using With:

Manipulate[
  With[{c = c}, 
    RegionPlot[{x^2 + y^2 <= c, x < 0}, {x, -Pi, Pi}, {y, -Pi, Pi}, 
      PlotLegends -> "Expressions"]
  ],
  {{c, 3.}, 0., 10., 0.1}
]