Study the possible coincidences of the three clock hands hour, minute, and second

Question

Inspired by the very nice problem solutions of the problem of coinciding clock hands, I'd like to extend the question including a "second" hand.

While it is obvious that all three hand can coincide only at midnight, the questions are

(i) where is the "second" hand after midnight when minute and hour hands conincide, and in which case the angular difference is minimal.

(ii) Create a nice picture of the situation.

(iii) Study the coincidence combinations hour-second and minute-second and exhibit the position of the missing hand in each case

Answer 1

The coincidences of the hour and minute hand occur when the number of hours since midnight $h$ satisfies $\frac{1}{12}h = h - n$ for some integer $n$. (The left-hand side corresponds to the number of revolutions the hour hand has made; the right-hand side corresponds to the number of of revolutions the minute hand has made.) This can be rearranged to $h = 12 n/11$, or $s = 43200 n/11$ (where $s$ is the number of seconds since midnight. Using the ClockGauge command (thanks to @ubpdqn), we can do this pretty easily:

Table[ClockGauge[43200 n/11], {n, 0, 10}]

The coincidences of the hour & second hands, and of the hour & minute hands, are a little harder to show, simply because there are so many of them (719 hour-second coincidences in a 12-hour period, and 708 minute-second coincidences.) The following bits of code do the trick, though:

Manipulate[ClockGauge[43200 n/719], {n, 0, 719, 1}]  (*hour-second*)
Manipulate[ClockGauge[3600 n/59], {n, 0, 708, 1}]    (*minute-second*)

The equations here were found by much the same logic as above.

EDIT: If you want to display the precise times of the coincidences, insert the option

GaugeLabels -> {"Hour12", ":", "Minute", ":", "SecondExact"}

into the ClockGauge command above.

Answer 2

I have not spent sufficient time but perhaps. In the following, starting clock at 12:00 with red second hand, blue minute hand and green hour hand. "SM" animates first coincidence second and minute hand, "MH", minute and hour hands, "SH" second and hour hands. First number after after graphic is time to first coincidence in seconds and second is clock time. Adapt/modify...very bland but time poor.

Manipulate[
 Column[{Animate[
    Graphics[{Circle[], Red, pp[ts, time], Blue, pp[tm, time], Green, 
      pp[th, time]}], {time, 0, p}, AnimationRepetitions -> 1, 
    AnimationRate -> tim[p]], Row[{N@p, " seconds"}], 
   DateString[
    DatePlus[{2015, 5, 13, 12, 0, 0}, {N@p, "Second"}], {"Hour24", 
     ":", "Minute", ":", "Second"}]}], {{p, 
   ci[ts, tm]}, {ci[ts, tm] -> "SM", ci[tm, th] -> "MH", 
   ci[ts, th] -> "SH"}}, Initialization :> (ts = 60;
   tm = 60 60;
   th = 12 60 60;
   pp[u_, t_] := Arrow[{{0, 0}, {Sin[2 Pi t/u], Cos[2 Pi t/u]}}];
   ppm[u_, t_] := Line[{{0, 0}, {Sin[2 Pi t/u], Cos[2 Pi t/u]}}];
   ci[t1_, t2_] := 1/(1/t1 - 1/t2);
   tim[ci[ts, tm]] := 0.1;
   tim[ci[tm, th]] := 0.02;
   tim[ci[ts, th]] := 0.1)]

Obviously could be better with ClockGauge or annotations...

or perhaps prettier:

Manipulate[
 Animate[ClockGauge[
   DatePlus[{2015, 5, 13, 12, 0, 0}, {j, "Second"}],GaugeLabels->Automatic], {j, 0, p}, 
  AnimationRepetitions -> 1], {{p, ci[ts, tm]}, {ci[ts, tm] -> "SM", 
   ci[tm, th] -> "MH", ci[ts, th] -> "SH"}}]