0
$\begingroup$

I've looked through the other posts on rotating a function around the x or y axis and haven't had any luck.

my question is this how do i rotate the area between the functions $f(x)=x^2+1$, and $f(x)=2x^2-2$, whereby $x>0$ and $y>0$ and the region is bounded by the y and x axis.

This is a plot of the area I'm talking about.

enter image description here

Revolving the area around the y-axis is suppose to produce a vase, although I picture something of a shallow bowl.

Any help would be much appreciated. As I'm still quite new to Mathematica, an explanation of any code posted would be helpful.

$\endgroup$
3
  • $\begingroup$ Please include the code you are trying in your question $\endgroup$
    – bbgodfrey
    Commented May 8, 2015 at 0:30
  • $\begingroup$ RevolutionPlot3D[{x^2 + 1, 2 x^2 - 2}, {x, 0, Sqrt[3]}, PlotRange -> All, RevolutionAxis -> "Y"] this is the code I'm trying but its not giving me what i know it should look like $\endgroup$
    – errymerry
    Commented May 8, 2015 at 0:33
  • $\begingroup$ RevolutionPlot3D[{fx,fz},{t,t0,t1}] generates a plot of the surface obtained by rotating the parametric curve with x,z coordinates {fx, fz} around the z axis. So your input created a very different curve from what Plot shows. Check the documentation very carefully. $\endgroup$
    – LLlAMnYP
    Commented May 8, 2015 at 14:32

3 Answers 3

4
$\begingroup$

Not an answer but an extended comment on belisarius' answer.

I think the plot will look more like what I believe the OP is expecting if a few options are added.

Show[RevolutionPlot3D[#, {x, 0, Sqrt[3]},
  PlotRange -> {Automatic, Automatic, {0., Automatic}},
  MeshStyle -> None,
  Axes -> None,
  Boxed -> False,
  PlotStyle -> Opacity[.5]] & /@ 
    {2 x^2 - 2, x^2 + 1, Piecewise[{{0, 0 < x < 1}}, Null]}]

plot

Also note that I have put a bottom on the bowl.

$\endgroup$
3
$\begingroup$
Show[RevolutionPlot3D[#, {x, 0, Sqrt[3]}, MeshStyle -> None, 
                      PlotStyle -> Opacity[.5]] & /@ {2 x^2 - 2,  x^2 + 1}]

Mathematica graphics

$\endgroup$
2
  • 1
    $\begingroup$ shouldn't it have a flat bottom as the domain of this pair of functions is restricted to x>0 and y>0 ? $\endgroup$
    – errymerry
    Commented May 8, 2015 at 1:52
  • $\begingroup$ @errymerry I believe you can work that out easily by yourself ;) $\endgroup$ Commented May 8, 2015 at 3:34
2
$\begingroup$

Just for something different:

pp = ParametricPlot3D[{Sqrt[3] Cos[t], Sqrt[3] Sin[t], 4}, {t, 0, 
    2 Pi}, PlotStyle -> {Red, Thickness[0.04]}, Boxed -> False];
rp = RegionPlot3D[
   0 < x^2 + y^2 < 3 && 
    Max[0, 2 x^2 + 2 y^2 - 2] < z < x^2 + y^2 + 1, {x, -2, 2}, {y, -2,
     2}, {z, 0, 5}, Mesh -> None, PlotStyle -> Red, PlotPoints -> 200,
    PerformanceGoal -> "Quality", Boxed -> False];
Show[pp, rp, Axes -> False, Background -> Black]

Top ring just to deal with boundary of intersection...

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.