Does Mathematica get Pi wrong?

Question

I happened to watch a Youtube video on Pi. According to the video, the 1 millionth digit of Pi is 1. And here is another page of the first 1 million digits of Pi.

You can get the same answer from WolframAlpha.

However, if you let Mathematica to calculate the digits you will get:

N[Pi, 1000005]
....65200102821**3**0222`1000005.

You will notice the 1 millionth digit of Pi in Mathematica is 3, not 1. Is anything wrong here?

Actually, if you move back 32 digits, you can see the exact digits as in the video.

**5779458151**309275628320845315846520010282130222`1000005.

Updates:

According to the answers, you can obtain the correct digits by following commands:

1. Command from answer of @m_goldberg

   RealDigits[N[Pi, 1000001]][[1, -10 ;; -1]]

2. Similarly, you can convert the number to string, which is the answer of @Daniel_Lichtblau

   str = ToString[N[Pi, 1000001], InputForm];
   Characters[str][[1000002 - 9 ;; 1000002]]

3. RealDigits can extract specific digits as in the answer of @Mr.Wizard

   RealDigits[Pi, 10, 10, 9 - 1*^6]

The last one is much faster than others:

In[334]:= Timing[RealDigits[Pi, 10, 10, 9 - 1*^6]]

Out[334]= {0.036622, {{5, 7, 7, 9, 4, 5, 8, 1, 5, 1}, -999990}}

In[335]:= Timing[RealDigits[N[Pi, 1000001]][[1, -10 ;; -1]]]

Out[335]= {0.229211, {5, 7, 7, 9, 4, 5, 8, 1, 5, 1}}

If this problem is generalized to obtain 1 million digits after decimal mark, the first two commands may provide wrong results. As is mentioned in the answer of @Mr.Wizard, the result provided by RealDigits[Pi, 10, 10, 9 - 1*^6] is the 999,991 to 1,000,000 digits behind decimal mark, nevertheless how many digits before the decimal mark. But for the first two method these digits should be counted and subtracted from the result. For the second method, the decimal mark takes one character, which should be included in the calculation.

The first method can be modified to following codes to consider the digits before decimal mark, but enough digits must be obtained in the first command:

num = RealDigits @ N[Pi, 1000010];   
num[[1,999991+num[[2]];;1000000+num[[2]]]]

Conclusions

1. Command N does not guarantee to output exactly number of digits as the command requiring. Moreover, different results may be obtained in different version of Mathematica.

2. RealDigits with four arguments is the most efficient way to extract specific digits in a number.

3. Converting number to InputForm is another possible way to obtain the digits without RealDigits command.

Answer 1

You have selected the wrong digit. Mathematica gets the digit in the million-th decimal place right if the calculation is performed correctly.

 q = N[Pi, 1000010];
 RealDigits[q][[1, 1000001]]

1

I take the 1000001-th digit because RealDigits includes the integer part, 3.

Update

It is really important to use RealDigits to decide this question. Looking at the displayed full form number is not reliable because it shows extra digits added in the working precision needed to get the specified real precision. Consider

N[Pi, 20] // FullForm

  3.1415926535897932384626433832795028841971693993751058209749`20.

That's a lot more than the 20 digits asked for. However,

RealDigits @ N[Pi, 20]

{{3, 1, 4, 1, 5, 9, 2, 6, 5, 3, 5, 8, 9, 7, 9, 3, 2, 3, 8, 4}, 1}

gives the actual set of correct digits.

Answer 2

That N[Pi, 1000005] is simply showing guard digits as well as the certified digits. You can get some idea of this from the checks below.

npi = N[Pi, 10^6 + 5];
digits = RealDigits[npi];
digits[[1, -5 ;; -1]]
str = ToString[npi, InputForm];
StringLength[str]
Characters[str][[-(StringLength[str] - 10^6 - 1) ;; -1]]

(* Out[426]= {1, 3, 0, 9, 2}

Out[428]= 1000047

Out[429]= {"1", "3", "0", "9", "2", "7", "5", "6", "2", "8", "3", \
"2", "0", "8", "4", "5", "3", "1", "5", "8", "4", "6", "5", "2", "0", \
"0", "1", "0", "2", "7", "7", "9", "7", "3", "2", "6", "4", "`", "1", \
"0", "0", "0", "0", "0", "5", "."} *)

Answer 3

To complement the existing answers I would like to point out that these digits can be efficiently produced directly by RealDigits without the use of N etc.:

RealDigits[Pi, 10, 10, 9 - 1*^6]

{{5, 7, 7, 9, 4, 5, 8, 1, 5, 1}, -999990}

---

Regarding the updated question I believe you are still confused by the different index between the different methods. Please consider this example:

x = 5000 + 1/7;

ToString[N[x, 10]]
RealDigits[N[x, 10]]
RealDigits[x, 10, 10]
RealDigits[x, 10, 10, -1]

"5000.142857"

{{5, 0, 0, 0, 1, 4, 2, 8, 5, 7}, 4}

{{5, 0, 0, 0, 1, 4, 2, 8, 5, 7}, 4}

{{1, 4, 2, 8, 5, 7, 1, 4, 2, 8}, 0}

Note that the first three methods produce digits starting with 5000, whereas the last method starts from the right of the decimal place due to the index chosen. So if you use the last method you must index from the decimal, whereas the other methods must all index from the "left" most digit.