Double improper integral

Question

I am trying to compute the following double integral:

Integrate[(r BesselJ[0, r])/(
2 (r^2 + z^2)^(1/2)), {z, -Infinity, Infinity}, {r, 0, Infinity}]

Which evaluates to 1. However, changing the order of integration yields an error (integral does not converge).

Can it be assured that the result is indeed 1 or that the integral diverges? How could I verify the result? I guess a numerical integration to Infinity is not very precise.

Answer 1

The inverse square root term is responsible for the errors as it diverges logarithmically at infinity. You could do one step at a time and see if you agree with the procedure of introducing a regularizing term, doing the integral and then removing it.

int1 = Integrate[(r BesselJ[0, r])/(2 (r^2 + z^2)^(1/2)) Exp[-α z^2], 
                 {z, -Infinity, Infinity}, Assumptions -> {α > 0, r > 0}]

(* 1/2 E^((r^2 α)/2) r BesselJ[0, r] BesselK[0, (r^2 α)/2] *)

int2 = Integrate[int1, {r, 0, Infinity}]
(* (E^((1/4)/α) Sqrt[π] Erfc[1/(2 Sqrt[α])])/(2 Sqrt[α]) *)

Finally:

Limit[int2, α -> 0]
(* 1 *)

Answer 2

Here's another approach just to illustrate the difficulty with multiple integrals that are not absolutely (i.e. $L^1$) convergent.

The integral on any finite disk centered at the origin is zero.

So it would be natural to conclude that the integral over the whole {r,z} plane is zero.

In terms of polar coordinates:

Integrate[
 ((r BesselJ[0, r])/(2 (r^2 + z^2)^(1/2)) /. {z -> ρ Sin[θ], r -> ρ Cos[θ]}) ρ,
 {ρ, 0, a}, {θ, 0, 2 Pi}, Assumptions -> a > 0]
(*  0  *)

Integrate[
  ((r BesselJ[0, r])/(2 (r^2 + z^2)^(1/2)) /. {z -> ρ Sin[θ], r -> ρ Cos[θ]}) ρ,
  {θ, 0, 2 Pi}, {ρ, 0, a}, Assumptions -> a > 0]
(*  Integrate[1/2 a BesselJ[1, a Cos[θ]], {θ, 0, 2 π}, Assumptions -> a > 0]  *)

Quiet@Block[{a = #}, N@%] & /@ RandomReal[{0, 100}, 100] // Abs // Max
(*  3.9635*10^-14  *)

In cartesian {r, z} coordinates:

Integrate[
 (r BesselJ[0, r])/(2 (r^2 + z^2)^(1/2)),
 {r, -a, a}, {z, Sqrt[a^2 - r^2], Sqrt[a^2 - r^2]}, Assumptions -> a > 0]
(*  0  *)

Integrate[
 (r BesselJ[0, r])/(2 (r^2 + z^2)^(1/2)),
 {r, z} ∈ Disk[{0, 0}, a], Assumptions -> a > 0]
(*  0  *)

Etc.