How to customize the package editor interface?

Question

Is there a way to get rid of the unused space on the left of the package editor?

enter image description here

What is it's purpose if I configured Mathematica to not show In and Out names? (Using Mathematica 10.1).

I suppose it would be nice if that was tweakable, but it's probably not. — Jacob Akkerboom, Apr 27, 2015 at 19:25
@Kuba nice nice, your answer makes a lot of sense :P. I'll try to remember CellMargins :) — Jacob Akkerboom, Apr 27, 2015 at 21:17
Related: How to set Initialization Cell style to conform with custom stylesheet?. — István Zachar, Aug 11, 2016 at 9:50

Community · Accepted Answer · 2017-04-13 12:55:56Z

Quick fix for a specific file:

Ok, let's open new package File -> New -> Package.

It was second on my list of Notebooks[]. So:
```
package = Notebooks[][[2]]
```
This is a notebook as any other, it just has different stylesheet ("Package.nb") and we can modify it as any other:
```
SetOptions[ package, {
  StyleDefinitions ->  Notebook[{
     Cell[StyleData[StyleDefinitions -> "Package.nb"]], 
     Cell[StyleData["Code"], CellMargins -> {{0, 0}, {0, 0}}]
  }],
  ShowCellLabel -> False,
  ShowGroupOpener -> False}
]
```
(notice that we are styling "Code" cell as this is the default one)

General approach to modifying built in stylesheets

This was set just for that .m file. If you want to set it globally edit the Package.nb stylesheet.

It is not so easy, you need privileges to work in $InstallationDirectory, system packages are not Editable and you risk breaking base files.

Here is a way to go to avoid those problems: copy stylesheet to the $UserBaseDirectory, enable editing and do whatever you need:
```
CopyFile @@ ( FileNameJoin[
  {#, "SystemFiles", "FrontEnd", "StyleSheets", "Package.nb"}
] & /@ {
 $InstallationDirectory, $UserBaseDirectory
})

SetOptions[NotebookOpen @ %, {Editable -> True, Saveable -> True}]
```

Very well, worked, thanks! Any problems on doing that? Any info that could be hidden besides the In e Out messages? — Giovanni F., Apr 27, 2015 at 20:54
@Giovanni In and Out are still available, you just can't see which cells they are referring to. — Kuba, Apr 27, 2015 at 20:58
@Giovanni you could also lose the information whether the cell was evaluated in debug mode and possibly CellTags/cell labels could become invisible. All of these do not seem really standard for package development though. — Jacob Akkerboom, Apr 27, 2015 at 21:15

1 Answer 1