Plot axes are not exported to SVG properly in Mathematica 10.1

Question

In the past, I was able to export Mathematica plots as SVG files with relative ease. However, when I tried to do this recently, I found that the text in the plot axes was rendered completely illegible, with all the characters being much too large, and all characters in a text element piling up on one another. Here is an screenshot of such a mangled plot:

The SVG file was produced with the following command:

Export["~/Desktop/test-m10-1.svg",
 Plot[Sin[x], {x, 0, 10}]]

While I don't have Mathematica 10.0 installed on this machine, I do have Mathematica 9, and this command works correctly in 9. Looking at the generated SVG as XML, it looks like the "text" elements that represent the labels on the axes in the SVG generated by M9 have somehow been replaced by "symbol" elements in M10.1.

FWIW, this was done on a machine running Mac OS 10.9.5.

EDIT: I tried using this svgExport routine, and it resulted in an SVG file which had the axes and tick labels displaying correctly, but didn't actually show the curve.

Answer 1

After some experimentation, I discovered that the issue preventing svgExport from working was that string replacements which add attributes caused multiple copies of the width and height attributes to be inserted. To avoid that, I rewrote it to use rule replacements on the symbolic representation of the XML instead of string replacement. The result is rather more verbose, but it's also more robust:

roundtripPDF[gr_, opts : OptionsPattern[]] :=
  First@ImportString@ExportString[gr, "PDF", opts];

asXML[gr_] := 
  ImportString[ExportString[gr, "SVG"], "XML", "ReadDTD" -> False];

addComment[None, elt_] := elt;
addComment[Automatic, elt_] := 
  addComment["*** Exported from Mathematica ***", elt];
addComment[comment_String, XMLElement[tag_, attrs_, contents_]] :=
  XMLElement[tag, attrs, 
   Append[contents, XMLObject["Comment"][comment]]];

addAttributes[oldAttrs_, newAttrs_] := 
  DeleteDuplicatesBy[Join[oldAttrs, newAttrs], First];

Options[Pillsy`ExportSVG] := {Background -> Automatic, 
   AspectRatio -> Automatic, "CommentString" -> Automatic};

Pillsy`ExportSVG[file_String, expr_, opts : OptionsPattern[]] :=
 With[{
   svgStructure = asXML@roundtripPDF[expr, opts],
   dims = 
    ToString /@ 
     ImageDimensions@
      Rasterize[Show[expr, ImagePadding -> 0], "Image"]
   },
  Export[
   file,
   svgStructure /.
    XMLElement["svg", attrs_, contents_] :>
     addComment[
      OptionValue["CommentString"],
      XMLElement["svg",
       addAttributes[attrs,
        Join[
         {"viewBox" -> "0 0 " <> StringRiffle[dims],
          "width" -> dims[[1]] <> "pt",
          "height" -> dims[[2]] <> "pt"},
         If[OptionValue[AspectRatio] === Full,
          {"preserveAspectRatio" -> "none"},
          {}]]],
       contents]], "XML"]]