Assignments in ParallelDo when using indexed variables

Question

For convenience I use an indexed variables syntax to hold results of long computations for different integer parameters:

zeros[30] = longComputation[30]
zeros[40] = longComputation[40]
(* etc *)

I need to execute these computations for several values of the parameter. Since computations are completely independent, I thought that I could speed it up somewhat by evaluating these computations in parallel:

SetSharedVariable[zeros]

ParallelDo[
  zeros[n] = longComputation[n],
  {n, 30, 70, 10}
]

This does not work, however. I'm getting error messages like this one from each kernel:

Set::write: Tag Null in Null[30] is Protected.

and zeros[n] have weird values assigned to them:

In[171]:= zeros[30]
Out[171]= Null[30]

What's going on here and how to do what I want?

Answer 1

You have to replace SetSharedVariable with SetSharedFunction.

longComputation[n_] := n

SetSharedFunction[zeros]

ParallelDo[
 zeros[n] = longComputation[n],
 {n, 30, 70, 10}
 ]

Why? From the docs of SetSharedVariable:

Shared variables without a value evaluate to Null.

This is what was happening to you, because zeros[30] = ... defines a function (also known as a "downvalue"), not a variable. You can read more about this here. Among those types of values mentioned in that post functions correspond to downvalues and variables correspond to ownvalues.

Answer 2

In this case you would need SetSharedFunction as you are dealing with DownValues. However, the communication overhead you introduce with this is likely going to negate any benefits or parallelization. Try to write parallel code that never requires write access to the same variable from different threads. Reformulate your problem in terms of ParallelMap or ParallelTable.

For example, why not this?

ParallelMap[{#, longComputation[#]}&, {30, 70, 10}]