This maybe a simple question, but I am just stuck with it. I want to do some simulation, say with 0.9 probability, I get a 1, and 0.1 probability get a 0.
How would I do that? Where should I start?
Thanks!
$\begingroup$
$\endgroup$
5
3 Answers
$\begingroup$
$\endgroup$
4
BernoulliDistribution is a perfect fit for this.
RandomVariate[BernoulliDistribution[1 - 0.1], {50}]
{1, 1, 1, 0, 1, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 1, 1, 1, 1}
Also, as kguler states, you can use RandomChoice, but the benefit of BernoulliDistribution is that you can operate it also as an abstract distribution, not only a source of randomness. For instance, you can compute its symbolic variance:
Variance[BernoulliDistribution[1 - 1/n]]
(1 - 1/n)/n
-
7$\begingroup$
RandomChoicedoes have the benefit of being compilable, unlikeBernoulliDistribution[]. $\endgroup$ Commented Apr 4, 2015 at 22:29 -
1$\begingroup$ @MichaelE2 Are you sure?
f = Compile[{{n, _Integer}}, RandomChoice[{.9, .1} -> {1, 0}, n]]seems to compile for me, with the functionRandomChoiceWeightsin the result ofCompilePrint$\endgroup$ Commented May 11, 2015 at 19:20 -
$\begingroup$ @blochwave, Oops, my bad. I forgot the
_Integeron that one but not the others. :/ Now the compiled version is faster until about 10^4 or 10^5. Sorry for the noise. $\endgroup$ Commented May 11, 2015 at 19:36 -
$\begingroup$ No problem! Admittedly performance tails off for large samples... $\endgroup$ Commented May 11, 2015 at 19:57
$\begingroup$
$\endgroup$
6
RandomChoice[{.9, .1} -> {1, 0}, 10]
(* {0, 1, 1, 1, 1, 1, 1, 0, 1, 1} *)
Timing results
Timing[RandomVariate[BernoulliDistribution[.9], {10^8}];](* {3.38014, Null} *)Timing[RandomChoice[{.9, .1} -> {1, 0}, 10^8];](* {5.64937, Null} *)dist[] := If[RandomReal[] > 0.9, 0, 1]; Timing[Table[dist[], {i, 10^8}];](* {13.9842, Null} *)
One nice property of RandomChoice is that it can be generalized, for instance:
RandomChoice[{.7, .2, .1}-> {0, 1, 2}]
answered Apr 4, 2015 at 21:11
-
$\begingroup$ "One nice property of RandomChoice is that it can be generalized..." - so too can BernoulliDistribution... $\endgroup$– ciaoCommented Apr 5, 2015 at 1:43
-
$\begingroup$ @rasher How can the
BernoulliDistributionbe generalized to give the same asRandomChoice[{.3, .2, .4, .05, .05}-> {-2, 5, 3, 2, "A"}]naturally, i.e., without multiple calls? $\endgroup$ Commented Apr 5, 2015 at 2:28 -
$\begingroup$ Multiple Bernoulli is just Multinomial, hence, with one call to multinomial, this gives same kind of results as RandomChoice:
RandomSample@ Flatten@MapThread[ ConstantArray[#1, #2] &, {#3, RandomVariate[MultinomialDistribution[#1, #2]]}] &given count, probs. and returned values... no real reason to do so, but it is one call to a distribution ;=) $\endgroup$– ciaoCommented Apr 5, 2015 at 3:47 -
$\begingroup$ @rasher Could you give a working example, with actual values (as I did)? For instance, I couldn't see how to get your example to work with five probabilities and five variables. Thanks. $\endgroup$ Commented Apr 5, 2015 at 3:54
-
$\begingroup$ Sure, e.g.
RandomSample@ Flatten@MapThread[ ConstantArray[#1, #2] &, {#3, RandomVariate[ MultinomialDistribution[#1, #2]]}] &[20, {.3, .2, .4, .05, \ .05}, {-2, 5, 3, 2, "A"}]gives same kind of result asRandomChoice[{.3, .2, .4, .05, .05}-> {-2, 5, 3, 2, "A"},20]. But again, no real reason to do this (I suppose if one were generating the dist. probs. programmatically and wanted to use probabilistic functions against them also this has a place) - just some gentle leg-pulling... $\endgroup$– ciaoCommented Apr 5, 2015 at 4:28
$\begingroup$
$\endgroup$
1
Take a uniform random distribution and check if it is above some threshold (0.9 in your case).
For example:
dist[] := If[RandomReal[] > 0.9, 0, 1];
Table[dist[], {i, 100}]
-
3$\begingroup$ No need for the
iin the iterator. $\endgroup$ Commented Apr 4, 2015 at 21:50
RandomChoise[{1,1,1,1,1,1,1,1,1,0}]assuming thatRandomChoisehas a constant probabality of choosing every element $\endgroup$RandomChoice[{0.1, 0.9} -> {0, 1}, n]to do the weighting instead, it's much more flexible this way. $\endgroup$