105
$\begingroup$

I've always wished I could do some profiling like you get in Wolfram Workbench, but directly from Mathematica, without using or having Workbench. If it is possible, how can I do it?

Improve this question
$\endgroup$
2

3 Answers 3

Reset to default
105
$\begingroup$

You can put your Mathematica session in debug mode by going to Evaluation->Debugger

Then, make some definitions and wrap the profiled code in RuntimeTools`Profile

For example, in debug mode, run

f[x_] := x^2

Table[f[x], {100000}]; // RuntimeTools`Profile

and you get a nice

Mathematica graphics

As @acl mentioned in the comments, clicking in the gray area in the output notebook's lines takes you to the related code

Improve this answer
$\endgroup$
10
  • 1
    $\begingroup$ Any idea, why test[] := Module[{}, Print["Here"]; Pause[0.1]; Print["There"]; Pause[1]; Return[2]] and test[] // RuntimeTools`Profile does not work, even though your example works correctly? $\endgroup$
    – Ajasja
    Jul 2, 2012 at 8:37
  • 6
    $\begingroup$ Unfortunately this solution does not seem to work for more complicated constructs, like funcitons called within Module, etc.. $\endgroup$
    – Wizard
    Oct 17, 2014 at 11:40
  • 4
    $\begingroup$ @Wizard Have you tried wrapping your entire code, definitions and all, in RuntimeTools`Profile? This seems to work for me. I suspect that certain profiling handles have to be silently inserted by this function for the timings to be gathered. Can you give me an example where this method fails? $\endgroup$
    – Mr.Wizard
    Jan 12, 2015 at 11:42
  • 1
    $\begingroup$ My issues mentioned in the comment above seem to be resolved in Mathematica 10.1. I also think that Mr.Wizard's suggestion should work in older versions, but I am not sure if I recall that correctly. Sorry for the late reply. $\endgroup$
    – Wizard
    Jul 9, 2015 at 11:13
  • 9
    $\begingroup$ @Wizard for the first time, I realize that there are at least two Wizards living on this site:-) $\endgroup$
    – matheorem
    Oct 11, 2015 at 8:47
5
$\begingroup$

Not knowing about the built in functions for this, I compiled these two functions. Hope they help someone. 

(* Test Performance of expression evaluation *)
benchmark[locals_,expr_,opts:OptionsPattern[]]:=Module[
{timeLst,funcs,stats,totalTime,times=OptionValue[times],run},
progressBar[Dynamic[run],times];
totalTime=AbsoluteTiming[
    timeLst=Table[
        Module[locals,
            ReleaseHold@AbsoluteTiming[expr]][[1]],
        {run,times}]][[1]];
If[OptionValue[printStats],
    styledPrint[{"Stats for ",times," runs of '", HoldForm[expr] ,"':"},Bold,20];
    statsSummary[timeLst];
    (styledPrint[{"Total Time: ", NumberForm[totalTime,3]},16])];
Return[{stats,timeLst}]
];

SetAttributes[benchmark,HoldAll];
Options[benchmark]={printStats->True,times->9};
benchmark::usage="benchmark[locals_,expr_,OptionsPattern[]] takes a list of localized var=val assignments (which are evaluated anew each run) (lexical, via Module). The expression is evaluated the given number of times, and statistics are printed about it.
The {list of statistics, list of individual runtimes} are returnd.

Example:
benchmark[{n=RandomInteger[10^3,10^5]},FactorInteger[n],times->10]

Options:
times:9 # to run the expression and collect runtime data
printStats:True Wether to print statistics about the distribution of times.
";

(* Compare performance of two expressions *)
compareRunTimes[locals_,base_,comp_,opts:OptionsPattern[]]:=Module[
{timeLst,baseTimeLst,compTimeLst,totalTime,ratio,times=OptionValue[times],runtimes=0,llocs},
progressBar[Dynamic[runtimes],times];
totalTime=AbsoluteTiming[
    timeLst=Map[
        With[locals,
            Evaluate[ReleaseHold@OptionValue[init]];runtimes=#;
            {ReleaseHold@AbsoluteTiming[base][[1]],
             ReleaseHold@AbsoluteTiming[comp][[1]]}]&,
        Range[times]]][[1]];
{baseTimeLst,compTimeLst}=Transpose@timeLst;
If[OptionValue[printStats],
    ratio=(Plus @@ compTimeLst)/(Plus @@ baseTimeLst);
    Quiet[styledPrint[{HoldForm[comp], Style[" (right)",Blue], " took ", Style[(ToString@NumberForm[100. ratio,3]) <> "%", If[ratio>1,Red,Green]], " as much time to evaluate as much as ", HoldForm[base], Style[" (left)", Blue], "!"},24,Bold],{NumberForm::sigz}];
    styledPrint[{"Stats for time ratios for ",times," runs of '", HoldForm[comp], "' and '", HoldForm[base] ,"':"},Bold,20];
    statsSummary[compTimeLst/baseTimeLst,total->False];
    styledPrint[{"Stats for ",times," runs of '", HoldForm[base] ,"':"},Bold,20];
    statsSummary[baseTimeLst];
    styledPrint[{"Stats for ",times," runs of '", HoldForm[comp] ,"':"},Bold,20];
    statsSummary[compTimeLst];];
Return[{baseTimeLst,compTimeLst}]
];

Options[compareRunTimes]={printStats->True,times->9,init->Null};
SetAttributes[compareRunTimes,HoldAll];
compareRunTimes::usage="compareRunTimes[locals_,base_,comp_,OptionsPattern[]] takes a list of localized var=val assignments (which are evaluated anew each run) (lexical, via Module). The expressions base and comp is evaluated the given number of times (with the same local calculated values for both), and statistics are printed about it.
The {list of statistics, list of individual runtimes} are returnd.

Example:
compareRunTimes[{s=RandomInteger[10^5,100000]},FactorInteger[s],FactorInteger[s (s+1)],times\[Rule]10]

Options:
times:9 # to run the expression and collect runtime data
printStats:True Wether to print statistics about the distribution of times.
";
Improve this answer
$\endgroup$
5
$\begingroup$

Since at least 2020, Wolfram provides Instrumentation package for profiling Wolfram Language code.

It seems to provide a very detailed report, e.g. I've got the following by profiling couple of my packages:

enter image description here

Improve this answer
$\endgroup$
10
  • $\begingroup$ Are the following lines in that link compulsory ? The first one: "Next we must instrument the code to be profiled" (I do not know what that means and do not understand what the code is doing) . The second one that follows : "Copy the original files to a temporary location" $\endgroup$
    – userrandrand
    Dec 27, 2022 at 22:46
  • 1
    $\begingroup$ Instrumentation works by modifying the source code: essentially, all the function calls are wrapped with functions that collect the necessary statistics (number of calls, time of execution, etc.). You don't want to do this with the original file - hence the suggestion in the Tutorial. $\endgroup$
    – Victor K.
    Dec 27, 2022 at 22:49
  • $\begingroup$ I see thank you for the clarification. I suppose that it suffices to make a separate copy in a separate folder and then just do the analysis directly on that copy. $\endgroup$
    – userrandrand
    Dec 27, 2022 at 22:54
  • 1
    $\begingroup$ There is also a resource function ResourceFunction["EvaluationTiming"][eval, "PackageName"] // Dataset` but this might be more detailed $\endgroup$
    – userrandrand
    Dec 27, 2022 at 23:17
  • $\begingroup$ Interesting; however, I'm not sure how to interpret this function results. e $\endgroup$
    – Victor K.
    Dec 27, 2022 at 23:24

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.