# Working with derivative of conjugate of a complex number

I have a complex function, lets say $g(x)$. I want to take its and its conjugate's derivative. I need the solution of derivative which must be symbolically and computationally efficient.
Lets take an example:

Derivative[g][x_] := d[g[x]]

Derivative[Conjugate][g[x_]] := Conjugate[d[g[x]]]/d[g[x]];
Derivative[Conjugate][d[x_]] := Conjugate[d[d[x]]]/d[d[x]]

Derivative[d][x_] := d[d[x]]/d[x];
Derivative[d][x_Symbol] := d[d[x]]


This will give me an effective symbolic representation of the derivative of $g(x)$ and $Conjugate(g(x))$ as d[g[x]] and Conjugate[d[g[x]]] but when I have to plug the analytical complex expression of $g(x)$ in d[g[x]], it will not compute the derivative of $g(x)$ instead gives only the symbolic representation of $d(g(x))$, which is computationally inefficient.
Is something can be done which is capable of symbolic as well as algebraic computation.

P.S. I do need the symbolic representation of the derivatives of conjugate in the above format only.

Maybe you can use the following two constructs to your advantage, which will keep the Conjugate, but evaluate and simplify the derivative inside. Using ReleaseHold, you can then evaluate even the Conjugate.

Note that I left out the divisor in the Conjugate-case for clarity, but you can easily add that into the second function's definition.

d[g_] := Derivative[g]
d[Conjugate[g_]] := With[{dg = d[g]@# // Simplify},
HoldForm[Conjugate[dg]] &]

(* example function *)
g[x_] := TrigToExp@Sin[x]

(* evaluation *)
d[g][x]
(* \[ExponentialE]^(-\[ImaginaryI] x)/2+
\[ExponentialE]^(\[ImaginaryI] x)/2 *)

d[Conjugate[g]][x]
(* Conjugate[1/2 \[ExponentialE]^(-\[ImaginaryI] x)
(1+\[ExponentialE]^(2 \[ImaginaryI] x))] *)


## Update

If you want further derivatives, you can instead use this slight expansion of the idea above:

d[g_, n_:1] := Derivative[n][g]
d[Conjugate[g_], n_:1] := With[{dg = d[g, n]@# // Simplify}, HoldForm[Conjugate[dg]] &]


n gives the order of derivation you want. If left out, the first derivative is generated.

Interesting sidenote: n can even be negative, giving you the integral of your function. Observe e.g.:

h[x_]:=Sin[x]
d[h,0][x]       (* Sin[x] *)

d[h,-1][x]      (* -Cos[x] *)

d[h,1][x]       (* Cos[x] *)
d[h][x]         (* Cos[x] *)

• Thanks for your input. Can you please tell me, where to read from to understand such programming in mathematica in a better way? I couldn't find this type of programming in any textbooks. – Shivam Sahu Mar 20 '15 at 13:53
• @ShivamSahu: I can only speak for myself: I learned the little I know about Mathematica from its documentation and my own humble experiments. If my answer helped in your quest, please "accept" it. – Jinxed Mar 20 '15 at 20:27
• I have one more question. How can we handle double derivative of g(x) and Conjugate(g(x)) with this? – Shivam Sahu Mar 22 '15 at 12:31
• @ShivamSahu: Have a look at the update I made to my answer. :) – Jinxed Mar 24 '15 at 13:49
• Thanks for the update. This was precisely what I was looking for. :) – Shivam Sahu Mar 25 '15 at 5:06