Question about VertexTextureCoordinates

Question

Background: consider the following snippet:

 gp := Graphics
 bill = Import["https://i.stack.imgur.com/FyojA.jpg"];
 poly1 = {{1, 0}, {.5, .86}, {-.5, .86}, {-1, 0}, {-.5, -.86}, {.5, -.86}};
 g1 = {Texture[bill], Polygon[poly1, VertexTextureCoordinates -> poly1]};
 poly2 = {{0, 0}, {1, 0}, {1, 1}, {0, 1}};
 g2 = {Texture[bill], Polygon[poly2, VertexTextureCoordinates -> poly2]};
 g1 // gp
 g2 // gp

The option VertexTextureCoordinates isn't entirely clear to me. I want to put an image with the correct ratios in the hexagon left. So for example on {{-.5,-.5},{.5,-.5},{.5,5},{-.5,.5}}. (I have not been able to get this to work although I have tried all sort of possibilities) However with the restriction that if I rescale the (coordinates of the) hexagon the image should be scaled accordingly.

EDIT-1: Image as requested.

EDIT-2: This nicely sums up and demonstrates the answer by Heike:

 rescale1[poly_, p1_, p2_] := 
  Transpose[{Rescale[poly[[All, 1]], {p1[[1]], p2[[1]]}, {0, 1}], 
    Rescale[poly[[All, 2]], {p1[[2]], p2[[2]]}, {0, 1}]}]
 Manipulate[
  g = {Texture[bill], 
     Polygon[poly, 
      VertexTextureCoordinates -> rescale1[poly, leftbot, righttop]]} //
     Graphics,
  {leftbot, {0, 0}, {1, 1}}, {righttop, {0, 0}, {1, 1}}, 
  Initialization :> {righttop = {1, 1}}, ControlPlacement -> Bottom]

Key is the mapping between the image and vertextexture coordinates.

Answer 1

As a generalisation of kguler and Verbeia's answers, you could do something like this

rescale[poly_] :=
  Module[{xrange, yrange, ratio, midp},
   xrange = Through[{Min, Max}[poly[[All, 1]]]];
   yrange = Through[{Min, Max}[poly[[All, 2]]]];
   midp = {Total[xrange], Total[yrange]}/2;
   Rescale[(# - midp) & /@ poly, 
    Max[yrange[[2]] - yrange[[1]], xrange[[2]] - xrange[[1]]]/2 {-1, 1}, {0, 1}]
   ];

Graphics[{Texture[bill], Polygon[poly1, VertexTextureCoordinates -> rescale[poly1]]}]

rescale is basically doing the same thing as the line Rescale[poly1,{-1,1},{0,1}] in the answers above except that the range over which to rescale is calculated automatically. This means that you can use it to rescale the vertex coordinates of any polygon without having to figure out the minimum and maximum values of the coordinates first, e.g.

SeedRandom[];
poly3 = (2 # + BlockRandom[RandomReal[{-1, 1}, 2]]) & /@ poly1;
Graphics[{Texture[bill], 
  Polygon[poly1, VertexTextureCoordinates -> rescale[poly1]],
  Polygon[poly3, VertexTextureCoordinates -> rescale[poly3]]}]

Edit

Concerning your comment, in the coordinate system used for specifying VertexTextureCoordinates, {0, 0} corresponds to the lower left corner of the image used for the texture and {1, 1} to the upper right corner. This coordinate system is cyclic with period 1 which means that for example the point {2.3, -0.8} corresponds to the same point in the image as the points {0.3, 0.2}. To align the texture with the polygon such that the points p1 and p2 (in the coordinate system of the polygon) correspond to the lower left and upper right corners of the image, you need to rescale the coordinates of the vertices of the polygon so that p1 will be mapped to {0, 0} and p2 to {1, 1}, for example by doing something like

rescale1[poly_, p1_, p2_] := Transpose[{Rescale[poly[[All, 1]], {p1[[1]], p2[[1]]}, {0, 1}],
  Rescale[poly[[All, 2]], {p1[[2]], p2[[2]]}, {0, 1}]}]

Graphics[{Texture[bill], 
  Polygon[poly1, 
   VertexTextureCoordinates -> rescale1[poly1, {-.5, -.5}, {.5, .5}]]}]

Here I've chosen p1 == {-.5, -.5} and p2 == {.5, .5} which will centre the texture.

Answer 2

kguler's answer is perfectly correct but I thought it worth mentioning that rescaling the Polygon itself is not necessary, only the vertices:

gp := Graphics
bill = ExampleData[{"TestImage", "Lena"}];

rawpoly = {{1, 0}, {.5, .86}, {-.5, .86}, {-1, 
    0}, {-.5, -.86}, {.5, -.86}};

poly1 = Rescale[rawpoly, {-1, 1}, {0, 1}];
g1 = {Texture[ExampleData[{"TestImage", "Lena"}]], 
   Polygon[rawpoly, VertexTextureCoordinates -> poly1]};

g1 // gp

The important point is that, regardless of the coordinates of the enclosing graphic, the VertexTextureCoordinates fall in a naturally rescaled unit square ({0,0} to {1,1}), and if the coordinates in this option fall outside this region, you end up with multiple tiles of the graphic, as seen in your question. If on the other hand, you rescale to a range that is smaller than the unit square, you will only show a portion of the picture but you can center the picture somewhere else in the graphic. Notice how the picture is displaced here relative to the first version.

rawpoly = {{1, 0}, {.5, .86}, {-.5, .86}, {-1, 
    0}, {-.5, -.86}, {.5, -.86}};

poly1 = Rescale[{{1, 0}, {.5, .86}, {-.5, .86}, {-1, 
     0}, {-.5, -.86}, {.5, -.86}}, {-0.5, 0.9}, {0.4, 1}];
g2 = {Texture[ExampleData[{"TestImage", "Lena"}]], 
   Polygon[rawpoly, VertexTextureCoordinates -> poly1]};
g2 // gp

Just for fun, proof that it was the scaling of the vertices, not the ordering, that was the issue:

g2 = {Texture[ExampleData[{"TestImage", "Lena"}]], 
   Polygon[rawpoly, 
    VertexTextureCoordinates -> RotateRight[poly1, 2]]};

Answer 3

Does this work?

lena=ExampleData[{"TestImage", "Lena"}];
poly1 = {{1, 0}, {.5, .86}, {-.5, .86}, {-1, 0}, {-.5, -.86}, {.5, -.86}};
scldpoly1=Rescale[poly1,{-1,1},{0,1}];
g1 = {Texture[lena],Polygon[scldpoly1,VertexTextureCoordinates -> scldpoly1]};

Graphics[g1]

or something like:

poly2 = {{-.5, -.5}, {.5, -.5}, {.5, .5}, {-.5, .5}}; 
Graphics[{Brown, Polygon[poly1], Texture[lena], 
Polygon[poly2, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}]

EDIT 3: For centered tiling shifting the polygon corrdinates by .5 does the centered tiling without having to use Rescale:

poly1X = poly1 - .5;
g1 = {Texture[ExampleData[{"TestImage", "Lena"}]], 
Polygon[poly1, VertexTextureCoordinates -> poly1X]};

Row[Graphics[{Texture[lena],Polygon[poly1, VertexTextureCoordinates -> # poly1X]}] & /@ Range[2, 5]]