3
$\begingroup$

I want to get the solution x of this equation

a (-(1/(1 + b c + a x)) - Log[b c + a x] + Log[1 + b c + a x]) - d = 0 

in terms of a, b, c, d. Solve and FindRoot do not give any answer!

$\endgroup$
7
$\begingroup$
Clear[a, b, c, x, d, r]
eq1 = a (-(1/(1 + b c + a x)) - Log[b c + a x] + Log[1 + b c + a x]) - d == 0

Mathematica graphics

To simplify, make common sub-expression substitution

eq2 = eq1 /. (b c + a x) -> z

Mathematica graphics

Write it as

eq2 = (-(1/(1 + z)) - Log[z] + Log[1 + z]) == d/a

Mathematica graphics

eq3 = eq2 /. (d/a) -> r

Mathematica graphics

Now take the exponential

eq4 = Exp[#] & /@ eq3

Mathematica graphics

eq5 = eq4 /. {(1 + z) -> k, z -> k - 1}

Mathematica graphics

Now reduce comes to help. We can either use Reduce on Reals or not. For the general case

Reduce[eq5, k]

Mathematica graphics

Using the last case for example:

eq6 = k == 1/(1 + ProductLog[C[1], -E^(-1 - r)])

Mathematica graphics

Now start back substitution

 eq7 = eq6 /. {k -> 1 + z, r -> (d/a)}
 eq8 = eq7 /. z -> (b c + a x)

Mathematica graphics

Now solve for x

 Solve[eq8, x]
 (*x -> (-1 - b c + 1/(1 + ProductLog[C[1], -E^(-1 - d/a)]))/a *)

Mathematica graphics

But notice there is arbitrary parameters C[1] which is an integer. So there are infinite number of solutions. Also, the other Reduce results are still applicable in this final solution

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.