Isolating cross terms

Question

I have a set of expressions that contains terms like $\frac{1}{(x + a + b)(c+d)}$. I would like to simplify the denominator so that products of $a,b,c,d$ are dropped, but $x c$ and $x d$ are kept. That is, the expression should be approximated as $\frac{1}{(c+d)x+a+b}$. One obvious way to do this is to use: 1/(Expand[Denominator[TheOriginalFraction]] /. {a*c -> 0, a*d -> 0, b*c -> 0, b*d -> 0}).

While this works, it's clunky and inconvenient for dealing with more complicated expressions. For example, a sum of several fractions of this form would require isolation of each fraction first, then pattern replacement, then reconstruction of the full expression.

Is there a more efficent and general method for this type of replacement/pattern matching?

Answer 1

Here is how I would do it:

expr = 1/((x + a + b) (c + d));

Limit[
  ϵ expr /. Thread[# -> ϵ #] &@Select[Variables[expr], # =!= x &],
 ϵ -> 0
]

(* ==> 1/(c x + d x) *)

I replaced all variables except x by ϵ times themselves and took the limit of ϵ times the original expression as ϵ goes to zero. This will leave only terms linear in the small variables in the denominator.

Answer 2

expr = 1/((x + a + b) (c + d));

Based on clipping by total degree. Let me make this answer more general.

ClearAll@expand
Options[expand] = {"SmallTerms" -> Automatic, "Order" -> 1, "Except" -> {}};

expand[expr_, OptionsPattern[]] := Module[{
   t,
   vars = Fold[
     DeleteCases,
     Flatten[{OptionValue["SmallTerms"]} /. Automatic -> Variables[expr] ], 
     Flatten[{OptionValue["Except"]}]]
   },
  Normal[Series[ expr /. Thread[vars -> t vars], {t, 0, OptionValue["Order"]}]
   ] /. t -> 1
  ]

You want to expand your denominator so:

Numerator[#] / expand[Denominator[#], "Except" -> {x}] & @ expr

1/(c x + d x)

usage examples:

expand[(1 + y) (X + X^2)]
expand[(1 + y) (X + X^2), "SmallTerms" -> X]
expand[(1 + y) (X + X^2), "Except" -> X]
expand[(1 + y) (X + X^2)^6 + y^2, "Order" -> 4, "Except" -> y]

X
X+X y
X+X^2+X y+X^2 y
y^2

Answer 3

I appreciate Jens's answer. However I want to answer literally

For example, a sum of several fractions of this form would require isolation of each fraction first, then pattern replacement, then reconstruction of the full expression.

Is there a more efficent and general method for this type of replacement/pattern matching?

Here are nice functions ExpandNumerator and ExpandDenominator. They didn't reconstruct sum of fractions

approx[expr_] := ExpandNumerator@ExpandDenominator@expr /. 
   Except[x, a_Symbol] Except[x, b_Symbol] :> 0

(a x + b)/((x + a + b) (c + d)) + (x^2 + 
     a) b/((x + a + b + f) (x + c + d) (x + g)) // approx

Of course, you can write more general patter. Note that ___ is unnecesary in Times since it orderless.

Answer 4

expr = 1/((x + a + b) (c + d));    

ExpandAll[expr] /. Times[v1_ /; v1 =!= x, v2_ /; v2 =!= x] :> 0

(*1/(c x + d x)*)

Answer 5

Given

expr = 1/((x + a + b) (c + d));
expr2 = 1/((x + a + b + f) (x + c + d));

While not the most elegant, this appears to do the trick

simpliFunc = Numerator[#] /
  Plus @@ Thread[
    Times[
      x^# & /@ Range[Length@Rest@CoefficientList[Expand@Denominator[#], {x}]],
      Rest@CoefficientList[ Expand@Denominator[#], {x}]
    ]
  ] &

simpliFunc@expr

Combined...

simpliFunc/@ (expr+expr2)

More complex examples:

expr4 = (a x + b)/((x + a + b) (c + d));
expr5 = (x^2 + x^b)/((x + a + b + f) (x + c + d));
expr6 = (b^x)/((x + a + b + f + g x^2) (x + c + d));

simpliFunc /@ (expr4 + expr5 + expr6)

Answer 6

expr1 = 1/((x + a + b)  (c + d));

(*TransferOrbit's examples*)

expr2 = 1/((x + a + b + f)  (x + c + d));
expr3 = (a  x + b)/((x + a + b)  (c + d));
expr4 = (x^2 + x^b)/((x + a + b + f)  (x + c + d));
expr5 = (b^x)/((x + a + b + f + g  x^2)  (x + c + d));

---

Another way is to use CoefficientRules:

SimplifyDenominator[expr_] := 
Divide @@ (FromCoefficientRules[#, x] & /@ 
MapAt[Most, CoefficientRules[#, x] & /@ NumeratorDenominator[expr], {2}])

SimplifyDenominator /@ {expr1, expr2, expr3, expr4, expr5} //     
Column[#, Spacings -> 1.5, ItemStyle -> 16] &