Normal[Series[ ]] does not give a normal expression

Question

Let us say I want to show how the Taylor's series for Sin behaves:

In[94]:= Plot[Normal[Series[Sin[x], {x, 0, 3}]], {x, -π, π}]

During evaluation of In[94]:= General::ivar: -3.14146 is not a valid variable. >>    
During evaluation of In[94]:= General::ivar: -3.14146 is not a valid variable. >>    
During evaluation of In[94]:= General::ivar: -3.14146 is not a valid variable. >>    
During evaluation of In[94]:= General::stop: Further output of General::ivar will be suppressed during this calculation. >>

However, if I just evaluate

In[95]:= Normal[Series[Sin[x], {x, 0, 3}]]

Out[95]= x - x^3/6

In[96]:= Plot[x - x^3/6, {x, -π, π}]

Out[96]=

It works fine. What is going on? I am doing this because I want to insert the plot in a Manipulate and then see how the functions behave with more terms of the series.

Update:

Using the answer, I can do

Plot[Evaluate@Normal[Series[Sin[x], {x, 0, 3}]], {x, -π, π}]

However, if I try to compare as in

Plot[{Sin[x], Evaluate@Normal[Series[Sin[x], {x, 0, 3}]]}, {x, -π, π}]

it doesn't work while the explicit Plot[{Sin[x], x - x^3/6}, {x, -π, π}] does.

Answer 1

As kguler shows this is an evaluation order problem.

I recommend a different form however:

Plot[
  {Sin[x], Normal[Series[Sin[x], {x, 0, 3}]]},
  {x, -π, π},
  Evaluated -> True
]

For Plot the undocumented option Evaluated is superior because the plotting variable (x) is still correctly localized, therefore this method works even if you set a global value e.g. x = 1 before plotting.

You asked why this doesn't work:

Plot[{Sin[x], Evaluate@Normal[Series[Sin[x], {x, 0, 3}]]}, {x, -π, π}]

This fails because as the Evaluate documentation under Possible Issues states:

Evaluate works only on the first level, directly inside a held function:

Hold[f[Evaluate[1 + 2]]]

Out[1]= Hold[f[Evaluate[1 + 2]]]

Answer 2

Try

 Plot[Evaluate@Normal[Series[Sin[x], {x, 0, 3}]], {x, -π, π}]

or

 Plot[#, {x, -π, π}] &@Normal[Series[Sin[x], {x, 0, 3}]]

or

 Plot[Normal[Series[Sin[y], {y, 0, 5}]] /. y -> x, {x, -Pi, Pi}]

to force evaluation in the appropriate order.

EDIT:

Plot[Evaluate@{Sin[x], Normal[Series[Sin[x], {x, 0, 3}]]}, {x, -Pi, Pi}]
Plot[{Sin[x], Normal[Series[Sin[x], {x, 0, 3}]]}, {x, -Pi, Pi}, Evaluated->True]
Plot[{Sin[x], #}, {x, -Pi, Pi}] &@Normal[Series[Sin[x], {x, 0, 3}]]
Plot[{Sin[x], Normal[Series[Sin[y], {y, 0, 3}]] /. y -> x}, {x, -Pi,  Pi}]

all give

EDIT 2: The error message

 General::ivar: "-3.14146 is not a valid variable."

suggests why Plot[Normal[Series[Sin[x], {x, 0, 5}]], {x, -Pi, Pi}] does not work. Namely, as Plot plugs numerical values x0 from the range (-Pi,Pi) in its first argument, the expression Series[Sin[x0], {x0, 0, 5}]] becomes an invalid expression.

EDIT 3: The option setting Evaluated->True in Mr.Wizard is most straightforward approach. The default setting for that option

 Options[Plot,Evaluated]
 (* ==> Automatic *)

By making the default setting for this option True using

SetOptions[Plot, Evaluated -> True];

you can use Plot[...] as usual.

An example:

 s = DSolve[y'[x] == 1/(1 + y[x]), y, x]; 
 Plot[ y[x] /. s /. C[1] -> Range[0, 5], {x, -5, 5}]