How can I replace the Greek symbols in an expression with their plain text names?

Question

Suppose I have an expression with Greek symbols in it. How would I convert that expression to another expression where the Greek symbols have been replaces with their names in plain text? I've included a small example of what I mean in the picture. Does anybody know of an easy way to do this?

Answer 1

Extract all Greek letters from the documentation and make replacement rules:

nb = Get @ FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", 
     "Tutorials", "LettersAndLetterLikeForms.nb"}];

letters = Cases[nb, StyleBox[s_String, "TR"] :> s, {-2}];

letters = DeleteCases[letters, "π" | "∈"];  (* reserved Symbols *)

names = StringTake[ToString @ FullForm @ #, {4, -3}] & /@ letters;

rules = MapThread[Symbol@# -> Symbol@ToLowerCase@#2 &, {letters, names}];

Then simply:

α x + β y /. rules

alpha x + beta y

---

If any of the Symbols may already have assignments and you are working with held expressions use instead:

rulesHeld = MapThread[HoldPattern @@ MakeExpression@# :> 
   Evaluate[Unevaluated @@ MakeExpression@ToLowerCase@#2] &, {letters, names}];

---

In a comment Oleksandr posted an undocumented System function which could be used as follows:

names = Join @@ System`Private`NameCodeLookup @ ToCharacterCode @ letters;

---

Complete replacement rules in case anything goes wrong with the extraction:

{α->alpha,  ρ->rho, Ε->capitalepsilon,  Ψ->capitalpsi
β->beta,    ϱ->curlyrho,    Ζ->capitalzeta, Ω->capitalomega
γ->gamma,   σ->sigma,   Η->capitaleta,  Ϝ->capitaldigamma
δ->delta,   ς->finalsigma,  Θ->capitaltheta,    Ϟ->capitalkoppa
ϵ->epsilon, τ->tau, Ι->capitaliota, Ϛ->capitalstigma
ε->curlyepsilon,    υ->upsilon, Κ->capitalkappa,    Ϡ->capitalsampi
ζ->zeta,    ϕ->phi, Λ->capitallambda,   Σ->capitalsigma
η->eta, φ->curlyphi,    Μ->capitalmu,   Π->capitalpi
θ->theta,   χ->chi, Ν->capitalnu,   ϵ->epsilon
ϑ->curlytheta,  ψ->psi, Ξ->capitalxi,   μ->mu
ι->iota,    ω->omega,   Ο->capitalomicron,  Υ->capitalupsilon
κ->kappa,   ϝ->digamma, Π->capitalpi,   ς->finalsigma
ϰ->curlykappa,  ϟ->koppa,   Ρ->capitalrho,  ϝ->digamma
λ->lambda,  ϛ->stigma,  Σ->capitalsigma,    ϟ->koppa
μ->mu,  ϡ->sampi,   Τ->capitaltau,  ϛ->stigma
ν->nu,  Α->capitalalpha,    Υ->capitalupsilon,  ϡ->sampi
ξ->xi,  Β->capitalbeta, ϒ->curlycapitalupsilon, 
ο->omicron, Γ->capitalgamma,    Φ->capitalphi,  
ϖ->curlypi, Δ->capitaldelta,    Χ->capitalchi}

(Sorry for the formatting; I can't think of a nice way to paste this here.)

Answer 2

EDIT:

I found a solution that is quicker than my previous answer in the case where the variables are Greek letters (like in the question by the original poster). The solution uses SpokenString and CharacterRange. The original answer below addresses the more general case of all named special characters.

(# -> ToExpression@ToLowerCase@SpokenString@# &) /@ 
 ToExpression /@ CharacterRange["α", "ω"]

(* {α -> alpha, β -> beta, γ -> gamma, δ -> 
  delta, ε -> curlyepsilon, ζ -> zeta, η -> 
  eta, θ -> theta, ι -> iota, κ -> 
  kappa, λ -> lambda, μ -> mu, ν -> nu, ξ -> 
  xi, ο -> omicron, π -> pi, ρ -> 
  rho, ς -> finalsigma, σ -> sigma, τ -> 
  tau, υ -> upsilon, φ -> curlyphi, χ -> 
  chi, ψ -> psi, ω -> omega} *)

---

Previous answer

The following code defines replacement rules that change all named characters like α to vAlpha and € to vEuro.

Code

rules = System`Private`CharacterNames[] // 
         Select[Not[StringTake[#, 3] == "Raw"] &] // 
        Map[ToExpression["\[" ~~ # ~~ "]"] -> 
           ToExpression["v" <> #] &] // Flatten // 
      DeleteCases[HoldPattern[$Failed -> _]] // 
     DeleteCases[HoldPattern[Null -> _]] // DeleteDuplicates // Quiet;

nameify[s_] := 
     s // ToString // Characters // ToExpression // ReplaceAll[rules] // 
        Map[ToString] // StringJoin // ToExpression

Explanation

As mentioned in the comments, SystemPrivateCharacterNames[] can be used to list all named characters.

However, I did not get the mentioned SystemPrivateNameCodeLookup to work.

I removed the named characters that started with raw as they seemed to often cause issues.

A syntax error will still happen which I ignored.

The code:

rules = System`Private`CharacterNames[] // 
         Select[Not[StringTake[#, 3] == "Raw"] &] // 
        Map[ToExpression["\[" ~~ # ~~ "]"] -> 
           ToExpression["v" <> #] &] // Flatten // 
      DeleteCases[HoldPattern[$Failed -> _]] // 
     DeleteCases[HoldPattern[Null -> _]] // DeleteDuplicates // Quiet;

For variables with lowercase names, instead of ToExpression["v" <> #] use: ToExpression@ToLowerCase[#]

We may then define a function that replaces a symbol like DΩ1 to Dcapitalomega1 :

nameify[s_] := 
 s // ToString // Characters // ToExpression // ReplaceAll[rules] // 
    Map[ToString] // StringJoin // ToExpression

test:

nameify[DΩ1]

(* Dcapitalomega1 *)