2
$\begingroup$

How to see (t,u) junction/nodes with a dot or a small circle connected by straight line in Mesh in 3D, but not as arcs generated by a large number of small steps of t and u.The command should, if possible modify existing ParametricPlot3D without use of Table and ListPlot3D. TIA

ParametricPlot3D[ { u Cos[t], u Sin[t],  1.2 u  }, { t, 0, 2 Pi}, {u, 1, 1.5},
  Mesh -> { 25, 5}]

enter image description here

$\endgroup$
1
  • $\begingroup$ @george2079 Thanks for image. $\endgroup$
    – Narasimham
    Feb 12, 2015 at 16:47

2 Answers 2

5
$\begingroup$

I am not sure I understand your question fully. Does this do what you are looking for?

ParametricPlot3D[{u Cos[t], u Sin[t], 1.2 u}, {t, 0, 2 Pi}, {u, 1, 1.5}, 
   Mesh -> Full, MaxRecursion -> 0, PlotPoints -> {25, 5}]

Mathematica graphics

It will not draw arcs, just straight lines between mesh points. The mesg corresponds to the sampled points precisely (thanks to Mesh -> Full), so the mesh density is now controlled by PlotPoints. MaxRecursion -> 0 prevents automatically refining the mesh.

If you wish to include small dots at the mesh line intersections, I don't believe it will be possible to avoid generating them using Table.

$\endgroup$
3
  • $\begingroup$ Thanks, Mesh-> Full plots nothing more than chosen sample points. $\endgroup$
    – Narasimham
    Feb 12, 2015 at 17:09
  • 1
    $\begingroup$ @Narasimham There's also Mesh -> All which shows the edges of the polygons (always triangles!) making up the object. Mesh -> Full will instead show just the rectangular mesh, not a triangular one. Both of them just use the sample points. $\endgroup$
    – Szabolcs
    Feb 12, 2015 at 17:11
  • $\begingroup$ +1, Mesh -> Full is definitely better. I forget that here is a difference between Full and All. $\endgroup$
    – ybeltukov
    Feb 12, 2015 at 17:35
5
$\begingroup$

Straight mesh lines can be obtaining by specifying corresponding plot points with zero max recursion. Then points can be drawn with post-processing (/. ... :> ...)

n1 = 10;
n2 = 3;
ParametricPlot3D[{u Cos[t], u Sin[t], 1.2 u}, {t, 0, 2 Pi}, {u, 1.0, 
   1.5}, Mesh -> {n1, n2}, PlotPoints -> {n1 + 2, n2 + 2}, 
  MaxRecursion -> 0, NormalsFunction -> None, PlotRange -> All, 
  BoundaryStyle -> Darker@Gray, MeshStyle -> Darker@Gray] /. 
 l : Line@p_ :> {Thickness[0.005], l, Sphere[p, 0.05]}

enter image description here

Here I also add NormalsFunction -> None to draw flat surface pieces.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.