Accessing chemical property data for specific conditions?

Question

There is a wealth of data for various chemicals available through Mathematica. For instance:

ChemicalData["Water", "Density"]
(* 1000. kg/(m)^3 *)

Module[{formula = ChemicalData["Water", "Formula"],
plot = ChemicalData["Water", "MoleculePlot"]}, Labeled[plot, formula, Bottom, Frame -> True]]

How does one ask for property data at specific conditions (i.e., temperature, pressure, phase, etc.)? I've been looking through the Wolfram help and tutorials, but I haven't run across this particular case.

It seems like this should be possible using queries to Wolfram Alpha as well, but I'd rather take advantage of native Mathematica functionality if it's available.

Answer 1

What you want here is ThermodynamicData. The available properties are

ThermodynamicData["Properties"] 

(* {"CriticalDensity", "CriticalEnthalpy", "CriticalEntropy", 
"CriticalInternalEnergy", "CriticalPressure", "CriticalTemperature", 
"Density", "Enthalpy", "Entropy", "InternalEnergy", 
"IsobaricHeatCapacity", "IsochoricHeatCapacity", 
"LiquidVaporPhaseBoundary", "MolarDensity", "MolarEnthalpy", 
"MolarEntropy", "MolarInternalEnergy", "MolarIsobaricHeatCapacity", 
"MolarIsochoricHeatCapacity", "MolarSpecificVolume", "Name", "Phase", 
"SolidLiquidPhaseBoundary", "SolidVaporPhaseBoundary", "SoundSpeed", 
"SpecificVolume", "ThermalConductivity", "TriplePointGasDensity", 
"TriplePointLiquidDensity", "TriplePointPressure", 
"TriplePointSolidDensity", "TriplePointTemperature", "Viscosity"} *)

But not all of those are functions of temperature or pressure. There is a list of properties which depend on these parameters in the documentation, but below I just filter them out.

propertiesTP = 
  ThermodynamicData["Properties"] // 
   DeleteCases[_?(StringMatchQ[#, 
        "Critical*" | "Triple*" | "*Phase*" | "Name"] &)];

temps = Quantity[Range[0, 99], "DegreesCelsius"];
ListLinePlot[
   Thread[
    {temps,
     ThermodynamicData["Water", #, {"Temperature" -> temps}]}
    ], AxesLabel -> Automatic, PlotLabel -> #, 
   ImageSize -> 250] & /@ propertiesTP

Answer 2

density = 
 Table[{i, 
   WolframAlpha[
    StringJoin["Water Density ", ToString[i], 
     " celsius"], {{"Result", 1}, "NumberData"}]}, {i, 1, 99}]

ListPlot[density, PlotTheme -> "Scientific", 
 FrameLabel -> {"Temperature (C)", "Density kg/m3"}, 
 PlotLabel -> "Water Density vs Temperature"]