Interact with external program

Question

I'm using NMinimize with Mathematica 7 using an external Fortran program to get the target value to minimize. I'm doing it using RunThrough with the variables as arguments in the command line.

This works, but I have to run the program for every possible candidate of NMinimize and is very slow (the program takes time to run and initialize).

I have made an interactive version of the program that will read the candidates from the standard input and write the resulting value to the standard output, but I cannot make it work in Mathematica. It seems that streams can be Input or Output only, so I cannot read and write to the stream at the same time, or get two different streams from a external execution command.

Documentation suggest using files for exchange but I'm not sure how to do that, not only in Mathematica but also in the Fortran code, to wait for a certain file to have new data instead of just returning EOF.

I've read the answer here: Is it possible to interact with an external program's command-line interface? but it doesn't address an interactive communication.

Any idea how to make Mathematica to open two In/Out streams to a external command?

Answer 1

Update -- finally got version 10

StartProcess version:

the fortran:

  program ptest
  real*8 x
  do while(.true.)
     read(*,*)x
     write(*,*)x**2*cos(x)+1.d0
  enddo
  end

this is a simple endless loop, reading from stdin and writing to stdout.

now in mathemaitca:

 pr = StartProcess["ptest"];
 f[x_?NumericQ] := (Write[pr, FortranForm[x]]; Read[pr, Number])
 NMinimize[f[x], x] // AbsoluteTiming
 KillProcess[pr]; (* dont forget to kill it.. remember the endless loop*)

{0.101721, {-10.6378, {x -> -3.6436}}}

Notice this is now comparable to native mathematica code (within a factor of 2 ).. nice!

---original RunThrough new-process-per-call version---

You can use RunThrough to pipe through stdin | fortran | stdout:

here has a minimal fortran example:

       real*8 x
       read(*,*)x
       write(*,*)x**2*cos(x)+1
       end

in mathematica:

      f[v_?NumericQ]:=RunThrough["path/file" , FortranForm[v] ]

      NMinimize[f[x],x]  //AbsoluteTiming

{17.993699, {-10.6378, {x -> -3.6436}}}

There are two essentials here.

• ?NumericQ is required else we pass a symbolic string "x" to fortran on the first pass
• FortranForm ( or equivalently CForm ) is needed so any numbers in scientific notation are properly formatted.

native mathematica is a "tad" faster by the way:

      NMinimize[ x^2 Cos[x] + 1  , x] // AbsoluteTiming

{0.062400, {-10.6378, {x -> -3.6436}}}

of course thats not a reflection on the performance of fortran, its slow due to all the overhead of starting up the executable for each eval.

RunThrough seem to need a full path by the way.

Answer 2

To call an external command with input parameters like *argv[] in C (I don't know how is it called in Fortran) you can use this Mathematica routine:

    RunProcess[{$SystemShell, "-c", ExecutableFileName <> " " <> arg1 <> " " <> arg2 <> " " <> arg3}, "StandardOutput"]

This will also give back output as a result of the routine. Then you can use this trick inside of the definition of your model function to get a value for some specific parameters of this function that you want to minimise. Then you can use NMinimize[] to find the minimum of this model function and the best values for parameters <=> the value of parameters at position of the minimum.