For anyone who has used LayeredGraphPlot (Mma v9), you have probably seen that the vertex spacing is consistent throughout, that vertices have the same minimum unit of spacing in the vertical and horizontal directions.

I know that changing AspectRatio will adjust one of the directions with respect to the other, but if I want to keep the existing aspect ratio, but want to space the vertices further apart (not resizing the overall graphic).

Without specifying the actual vertex potions using VertexCoordinateRules for each vertex, is it possible to change the vertical/horizontal spacing unit? For instance, if I just want all of the vertices to be spaced twice as far apart from each other in each direction as the default, can this be set?

UPDATE: For a given set a vertices LayeredGraphPLot chooses this minimum spacing unit, however, if you change the list of rules, or use a different set of rules (and hence how the vertices are connected), it will redraw it with different spacing, even though it could have been done using the spacing from the original set of rules, regardless of if you leave AspectRatio and ImageSize as free parameters or not. There may be an algorithm to avoid vertex crowding, but I don't see why the minimum unit spacing couldn't still be set anyway.

Here is an example, note that all of the red lines are the same size, depicting the constant unit dimension between vertices.

enter image description here

UPDATE 2: SquareOne's solution with two different data sets:

set1 = {"A" -> "B", "B" -> "C", "D" -> "F", "A" -> "F", "G" -> "B", "H" -> "C", "C" -> "G"};

enter image description here

set2 = {"B" -> "A", "B" -> "G", "D" -> "H", "A" -> "F", "G" -> "A", "H" -> "B", "F" -> "G"};

enter image description here

You can see, that with the same number of rules in the list (and hence the same number of edges), the same number of vertices, with the vertices being the same size (resizing the images), and the aspect ratios allowed to vary as needed to accommodate the plot, the edgelengths are very different.

UPDATE 3: SquareOne's solution has been modified to work for arbitrary datasets, I therefore accept his solution.

  • $\begingroup$ "not resizing the overall graphic" so e.g. ImageSize->700 can't be a solution. Could you explain why in more details? $\endgroup$
    – ybeltukov
    Commented Jan 30, 2015 at 13:07
  • $\begingroup$ @ybeltukov Let me edit my question to address this. $\endgroup$
    – iwantmyphd
    Commented Jan 30, 2015 at 13:12
  • $\begingroup$ Thanks, I see. Another related command is Graph with GraphLayout -> {"LayeredEmbedding", LayerSizeFunction -> (1 &), "LeafDistance" -> 1}. However the scaling of both parameters changes nothing. $\endgroup$
    – ybeltukov
    Commented Jan 30, 2015 at 14:05
  • $\begingroup$ @ybeltukov GraphLayout doesn't appear to be a valid command within LayeredGraphPLot (this is Mma 9.0.1). $\endgroup$
    – iwantmyphd
    Commented Jan 30, 2015 at 16:18
  • $\begingroup$ I mean Graph[Table[i <-> Mod[i + 1, 5], {i, 12}], GraphLayout -> {"LayeredEmbedding", LayerSizeFunction -> (1 &), "LeafDistance" -> 1}]. It works in both V9 and V10. $\endgroup$
    – ybeltukov
    Commented Jan 30, 2015 at 16:24

1 Answer 1


This answer is closely related to your previous post and to the answer I gave you then. They could actually be merged.


As requested, here is a new version of the function which let you change the scale of the edges while keeping the same unit length for any working set.

(I finally managed (not trivial) to get the width and height of the plot produced by the function LayeredGraphPlot ; these are needed in order to scale properly every elements in the rendering options);

As a bonus ;) the image size of the plots are now automatically scaled according to the unit length. Any other words you don't need anymore to resize manually the plots for different sets in order to compare them.

draw[set_, edgescale_: 1, aspectratio_: 0] :=
 Module[{width, height, ar0, ar, thicknessDisk = 0.18},
  {width, height} = 
   edgescale*(LayeredGraphPlot[set, Bottom, Axes -> False, 
         PlotRangePadding -> None][[1, 1, 1]] // Transpose // (Max@# - Min@#) & /@ # &);
  ar0 = height/width;
  ar = If[aspectratio == 0, ar0, aspectratio];
  LayeredGraphPlot[set, Bottom, VertexLabeling -> True, DirectedEdges -> True, 
   EdgeRenderingFunction -> ({Black, Thickness[0.1/width], Arrow[#1, 0.05]} &), 
   VertexRenderingFunction -> ({EdgeForm[{Black, Thickness[0.04/width]}], White, 
       Disk[#1, Scaled[{thicknessDisk/width, ar0*thicknessDisk/height/ar}]], 
       Black, Style[Text[#2, #1], FontFamily -> "Arial", Bold, 
        FontSize -> Scaled[0.2/width]]} &), 
   PlotStyle -> Arrowheads[{{0.3/width, 0.8}}], 
   PlotRangePadding -> 0., Axes -> False, AspectRatio -> ar, 
   ImageSize -> 75*(width + 2*thicknessDisk)]]


The example sets :

set1 = {"A" -> "B", "B" -> "C", "D" -> "F", "A" -> "F", "G" -> "B", "H" -> "C", "C" -> "G"}; 
set2 = {"B" -> "A", "B" -> "G", "D" -> "H", "A" -> "F", "G" -> "A", "H" -> "B", "F" -> "G"};

then put all this in one cell and run :

Print["set1 with edge scale = 2:"]; draw[set1, 2]
Print["set1 with edge scale = 1 and aspect ratio = 1:"]; draw[set1, 1, 1]
Print["set1 (default param.):"]; draw[set1]
Print["set2 (default param.):"]; draw[set2]

enter image description here

enter image description here

  • $\begingroup$ Thank you, I will try this. Perhaps the confusion was my using vertex spacing rather than edge length. To me, they are equivalent. I apologize if this was the cause of the confusion. If they are not equivalent, I'd greatly appreciate understanding how they differ. Thanks again. $\endgroup$
    – iwantmyphd
    Commented Feb 5, 2015 at 18:07
  • $\begingroup$ No problem, actually my knowledge in Graph Theory and its vocabulary is very poor ;) so i tried to express the problem in other more common words. $\endgroup$
    – SquareOne
    Commented Feb 6, 2015 at 11:22
  • $\begingroup$ I've now tested this, but it seems that even if I specify vertexscale, the edge length varies from dataset to dataset, so it seems that vertexscale has units that are unclear to me. In other words, setting vertexscale = 2 produces a different spacing from one data set to the next, when it shouldn't. $\endgroup$
    – iwantmyphd
    Commented Feb 14, 2015 at 1:27
  • $\begingroup$ @iwantmyphd Can you give me a simple example with this problem, I'll take a look. $\endgroup$
    – SquareOne
    Commented Feb 15, 2015 at 11:17
  • $\begingroup$ Yes, I've just uploaded two plots made from your exact code: one with the original rule set, and another with a new rule set that still has the same number of rules (edges), vertices, and vertex size, etc., and you can see the spacing from set1 to set2 differs. In your code, vertexspacing was set to 1, so the spacing in both plots should be the same, but isn't. $\endgroup$
    – iwantmyphd
    Commented Feb 15, 2015 at 17:36

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.