How to create a Disk with smoothly changing coloring?

Question

I want to have a disk. But this disk shouldn't have a fixed color; instead, I'd like it's color to fade smoothly.

Until now, I came up with two ideas how to achieve this.

Idea #1:

smoothlyFadingColorDisk1[r_] := 
 DensityPlot[Max[0, r - Sqrt[x^2 + y^2]], {x, -r, r}, {y, -r, r}, 
  ColorFunction -> (Opacity[#, Purple] &)]

Problems:

• It displays axes, and Axes->False won't remove them. This is meant to be just a part of a more complex graphics, so the axes are here completely inaproppiate. (blocking problem)
• This makes no sense semantically. I want a Disk (a simple image), not a plot.

Idea #2:

smoothlyShiftedColorDisk2[r_, n_] := 
 Graphics[Flatten@
   Prepend[{Thickness[1/(2*n - 1)]}]@
    Table[{Opacity[(n - i + 1)/n, Purple], 
      Circle[{0, 0}, (i - 1/2)*r/(n - 1/2)]}, {i, 1, n}]]

Problems:

• It looks bad at some values of n and horrible at others. This seems to be because for some reason (inaccurate floating point calculations? my mistake in the maths?) the concentric circles are overlapping, and they shouldn't. They should be ideally next to each other. (blocking problem)
• I have to manually set the number of colors used (the n variable, number of concentric cirlces). And I'd like Mathematica to take care of this for me, as happens in the first example.

So - neither of these two ideas acheves what I am trying to achieve. Er... How to do this properly?

I have a feeling that this should be possible to achieve in a much simpler way than I was trying to do this...

Answer 1

Both, DensityPlot and Graphics, with primitives like Circle and Disk, produce Graphics output. I think it is alright implementing your custom graphics.

Here's my take, following your second idea, with a simple control over how the opacity fades.

smooth[a_, R_: 1, n_: 100, hue_: Purple] :=
 Graphics@Table[{
    Blend[{Append[0]@hue, Append[1]@hue},
     Rescale[r, {R, R/n}, {0, 1}]^a],
    Disk[{0, 0}, r]}, {r, R, R/n, -R/n}]

GraphicsRow[smooth /@ {1, 2, 3, 4}, ImageSize -> 500]

GraphicsRow[smooth[2.5, 1, 50, #] & /@
  {Red, Orange, Yellow, Green}, ImageSize -> 500]

Update: Discarding alpha channel for opaque hues.

smooth2[a_, R_: 1, n_: 100, hue_: Hue[.65]] :=
 Graphics@Table[{
    Blend[{White, hue}, Rescale[r, {R, R/n}, {0, 1}]^a],
    Disk[{0, 0}, r]}, {r, R, R/n, -R/n}]

GraphicsRow[smooth2 /@ {1, 4/3, 5/3, 2},
 ImageSize -> 500]

Answer 2

Using Frame->False instead of Axes->False for your first approach seems to work well.

Answer 3

Another way:

   circim = Graphics[{White, Disk[]}, Background -> Black];
   ImageMultiply[LinearGradientImage[{Blue, Yellow, Red}], circim]

Or

ImageMultiply[RadialGradientImage[{Blue, Yellow, Red}], circim]

One can compose such a figure with transparency as:

ImageCompose[EiffelTower, {mybullseye, .5}]

where the .5 is the transparency (opacity) of the graded disk.

You can superimpose the bullseye on a simple graphic this way:

ImageCompose[Image[Plot3D[Sin[x y], {x, -2, 2}, {y, -2, 2}]], {mybullseye, .8}]