Cannot shade 3D vector in different color

Question

I need to color each vector into different colors... but this formula just doesn't work:

m = Axes3D[10];
n = ListPointPlot3D[{{4, 5, 6}, {3, -3, -6}, {2, 2, 5}}, 
   PlotLegends -> Automatic, ImageSize -> 400, 
   PlotStyle -> PointSize[0.03], PlotRange -> {-10, 10}];
o = Graphics3D[Arrow[{{4, 5, 6}, {3, -3, -6}}], Axes -> True, 
   Boxed -> False, ColorOutput -> Red](*vector a*);
r = Graphics3D[Arrow[{{4, 5, 6}, {2, 2, 5}}], Axes -> True, 
   Boxed -> False, ColorOutput -> Blue](*vector b*);
s = Graphics3D[Arrow[{{2, 2, 5}, {3, -3, -6}}], Axes -> True, 
   Boxed -> False, ColorOutput -> Black](*vector a-b*);
Show[m, n, o, r, s]

Answer 1

You haven't defined Axes3D[]. Nevertheless:

n = ListPointPlot3D[{{4, 5, 6}, {3, -3, -6}, {2, 2, 5}}, 
   PlotLegends -> Automatic, ImageSize -> 400, 
   PlotStyle -> PointSize[0.03], PlotRange -> {-10, 10}];
o = Graphics3D[{Red, Arrow[{{4, 5, 6}, {3, -3, -6}}]}, Axes -> True, 
   Boxed -> False];
r = Graphics3D[{Blue, Arrow[{{4, 5, 6}, {2, 2, 5}}]}, Axes -> True, 
   Boxed -> False];
s = Graphics3D[{Black, Arrow[{{2, 2, 5}, {3, -3, -6}}]}, Axes -> True,
   Boxed -> False];
Show[n, o, r, s]

Or... more simply:

Graphics3D[{
  {PointSize[0.03], Point[{{4, 5, 6}, {3, -3, -6}, {2, 2, 5}}]},
  {Red, Arrow[{{4, 5, 6}, {3, -3, -6}}]},
  {Blue, Arrow[{{4, 5, 6}, {2, 2, 5}}]},
  {Black, Arrow[{{2, 2, 5}, {3, -3, -6}}]}},
 Axes -> True,
 PlotRange -> {{-10, 10}, {-10, 10}, {-10, 10}}]

Or tighter code, with internal axes:

Graphics3D[{
  {PointSize[0.03], Point[{{4, 5, 6}, {3, -3, -6}, {2, 2, 5}}]},
  MapThread[{#1, Arrow[#2]} &, 
{{Red, Blue, Black}, 
{{{4, 5, 6}, {3, -3, -6}}, {{4, 5, 6}, {2, 2, 5}}, {{2, 2, 5}, {3, -3, -6}}}}]},
 Axes -> True,
 AxesOrigin -> {0, 0, 0},
 PlotRange -> {{-10, 10}, {-10, 10}, {-10, 10}}]