How can I plot a 3D graph that shows how a histogram varies with a particular parameter?

Question

How can I plot a 3D graph that shows how a histogram varies with a particular parameter?

A simple example of this would be plotting a histogram of data described by a gaussian. The gaussian is of unit height and centered on the origin so that the only parameters are x and a, where a describes the width of the gaussian.

Gaussian=Exp[-x^2/(2*a^2)]

I can then plot of histogram of the data for a given value of a. For example,

Gaussian1=Gaussian/.a->1
Table=[Gaussian1,{x,-20,20}]
Histogram[Table]

However what I want to show is how this histogram will change as a is varied. So what will be produced is a 3D graph, with the z axis as the bin count, x axis as x, and y axis as a. We should then see the histogram narrow as a increases, i.e. along along the y axis.

My actual code looks at the dispersion of electrons in a varying electric field. A histogram can be produced that shows the trajectories of electrons at any given time relative to a chosen direction, however I want to show how this dispersion changes with time, since the electric field itself is time varying.

Thanks in advance.

Answer 1

mydata = Table[
   {σ, RandomVariate[NormalDistribution[0, σ]]},
   {σ, 1, 10, .5}, {100}];

Histogram3D[mydata,
 AxesLabel -> Text[Style[#, Italic, 14]] & /@ {"σ", "x", "Count"}]

A prettier version, with the Gaussians superimposed:

mydata = Table[
   {σ, RandomVariate[NormalDistribution[0, σ]]},
   {σ, 1, 10}, {100}];

Show[
 Histogram3D[
  mydata,
  PlotRange -> {{0, 10}, {-20, 20}, {0, All}},
  AxesLabel -> (Text[Style[#, Italic, 14]] & /@ {"σ", "x", "Count"})],

ParametricPlot3D[
   Evaluate[
    Table[
     {σ + .5, x, 200 PDF[NormalDistribution[0, σ], x]},
     {σ, 1, 10, 1}]], {x, -20, 20},
   PlotRange -> {{-20, 20}, {0, 10}, {0, All}},
   PlotStyle -> Thick,
   BoxRatios -> {1, 1, 1}
   ]
 ]