I don't know if there is a built-in function for this, but I'm thinking about something like this
Outer[List, Table[{0,1},{n}] ]
But Outer doesn't accept this type of input. What should I do?
$\begingroup$
$\endgroup$
Add a comment
|
5 Answers
$\begingroup$
$\endgroup$
Tuples is surely better but you can make Outer work very simply too:
Outer[List, ##] & @@ Table[{0, 1}, {3}]
{{{{0, 0, 0}, {0, 0, 1}}, {{0, 1, 0}, {0, 1, 1}}}, {{{1, 0, 0}, {1, 0, 1}}, {{1, 1, 0}, {1, 1, 1}}}}
Also applicable is Array:
Array[List, {2, 2, 2}, 0]
{{{{0, 0, 0}, {0, 0, 1}}, {{0, 1, 0}, {0, 1, 1}}}, {{{1, 0, 0}, {1, 0, 1}}, {{1, 1, 0}, {1, 1, 1}}}}
Complete with flattening:
n = 4;
{Array[List, ConstantArray[2, n], 0, ## &]}
{{0, 0, 0, 0}, {0, 0, 0, 1}, {0, 0, 1, 0}, {0, 0, 1, 1}, {0, 1, 0, 0}, {0, 1, 0, 1}, {0, 1, 1, 0}, {0, 1, 1, 1}, {1, 0, 0, 0}, {1, 0, 0, 1}, {1, 0, 1, 0}, {1, 0, 1, 1}, {1, 1, 0, 0}, {1, 1, 0, 1}, {1, 1, 1, 0}, {1, 1, 1, 1}}
answered Jan 14, 2015 at 17:34
$\begingroup$
$\endgroup$
You could try Tuples:
Tuples[{0, 1}, 4]
(*
{{0,0,0,0},{0,0,0,1},{0,0,1,0},{0,0,1,1},
{0,1,0,0},{0,1,0,1},{0,1,1,0},{0,1,1,1},
{1,0,0,0},{1,0,0,1},{1,0,1,0},{1,0,1,1},
{1,1,0,0},{1,1,0,1},{1,1,1,0},{1,1,1,1}}
*)
$\begingroup$
$\endgroup$
3
While Tuples works well for generating all of them at once, sometimes we need to enumerate them one by one, without keeping all previous results in memory. In this case you can use
Do[ ... IntegerDigits[k, 2, n] ..., {k, 0, 2^n-1}]
answered Jan 14, 2015 at 17:22
-
$\begingroup$ What does the
...do? I get a syntax error when I execute it. $\endgroup$ Jan 14, 2015 at 19:47 -
1$\begingroup$ @DumpsterDoofus Nothing. It's not executable code, I meant that one might want to put other things in the
Doloop. $\endgroup$– SzabolcsJan 14, 2015 at 19:48 -
$\begingroup$ @Dumps I use
. . .for that purpose to reduce confusion withRepeatedNull; I'm not sure if it works. $\endgroup$ Jan 14, 2015 at 22:01
$\begingroup$
$\endgroup$
1
IntegerDigits[Range[2^5], 2, 5]
or as a function:
myList[n_: Integer] := Flatten[Array[List, Table[2, {n}], 0], n - 1]
But if you need to display the digits as a string rather than a comma-separated list:
StringJoin /@ Tuples[{"0", "1"}, 5]
What is your specific need for such sequences? That will help us help you.
answered Jan 14, 2015 at 17:27
-
1$\begingroup$ As to the second solution: don't forget
IntegerString:With[{n = 8}, IntegerString[#, 2, n] & /@ Range[2^n - 1]]. It's twice as fast. $\endgroup$ Jan 14, 2015 at 20:42
$\begingroup$
$\endgroup$
Distribute[ConstantArray[{0, 1}, 4], List] // TeXForm
$ \left( \begin{array}{cccc} 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 1 \\ 0 & 0 & 1 & 0 \\ 0 & 0 & 1 & 1 \\ 0 & 1 & 0 & 0 \\ 0 & 1 & 0 & 1 \\ 0 & 1 & 1 & 0 \\ 0 & 1 & 1 & 1 \\ 1 & 0 & 0 & 0 \\ 1 & 0 & 0 & 1 \\ 1 & 0 & 1 & 0 \\ 1 & 0 & 1 & 1 \\ 1 & 1 & 0 & 0 \\ 1 & 1 & 0 & 1 \\ 1 & 1 & 1 & 0 \\ 1 & 1 & 1 & 1 \\ \end{array} \right)$
