The code
Limit[Log[2 - Sin[x]*Cos[x]], x -> Infinity]
outputs
Interval[{0, Log[3]}]
in Mathematica 10.0.2.0 . It should be
Interval[{Log[3/2]}, Log[5/2]}]
instead of. Is there a workaround?
$\begingroup$
$\endgroup$
11
3 Answers
$\begingroup$
$\endgroup$
2
Slow down the approach,
Limit[Log[2 - Sin[x]*Cos[x]] /. x -> x/2, x -> Infinity]
or speed it up,
Limit[Log[2 - Sin[x]*Cos[x]] /. x -> 2 x, x -> Infinity]
-- both yield
Interval[{Log[3/2], Log[5/2]}]
answered Jan 14, 2015 at 22:54
-
-
1$\begingroup$ @Mr.Wizard I had an idea when I tried it, but not after looking at the
Trace, which was unilluminating. My feeling was that the transformationSin[2x] -> 2 Sin[x] Cos[x], getting the trig. fns. in terms ofx(e.g.TrigExpand), andSin,Cosbeing between±1might be tempting M. Changingxin the above and similar ways seems to work, perhaps by preventing the double angle formula from being applied. It was basically a guess. BTW, in my view of howLimitandIntervalwork, I think both results are "correct," although a more precise result is more desirable. $\endgroup$ Commented Jan 15, 2015 at 0:45
$\begingroup$
$\endgroup$
5
A limited kind of work-around:
expr = Log[2 - Sin[x]*Cos[x]];
TrigReduce //@ expr /. x -> Interval[∞]
Interval[{Log[3/2], Log[5/2]}]
answered Jan 14, 2015 at 17:51
-
$\begingroup$ Sorry, I don't see any Limit in your code. You found the range of expr = Log[2 - Sin[x]*Cos[x]];. $\endgroup$ Commented Jan 14, 2015 at 18:19
-
$\begingroup$ @user64494 Yes, it is not very general. The result is right in the particular case however, is it not? $\endgroup$ Commented Jan 14, 2015 at 18:21
-
$\begingroup$ @ Mr.Wizard: Could that be called a workaround? I think the answer is no. $\endgroup$ Commented Jan 14, 2015 at 18:26
-
$\begingroup$ @user64494 Hey, I'm trying. :^) $\endgroup$ Commented Jan 14, 2015 at 18:26
-
$\begingroup$ @user64494 Why do you say Mr.Wizard found the range? Other than the fact that your so-called limit is the same as the range, which is itself a source of confusion in any case, the computation does not represent finding the range. It more closely represents finding the limit. $\endgroup$ Commented Jan 14, 2015 at 22:44
$\begingroup$
$\endgroup$
2
f[x_] = Log[2 - Sin[x]*Cos[x]];
Simplify[f[x] == f[x + n Pi], Element[n, Integers]]
True
Since the function is periodic, the limit interval is just the minimum and maximum of the function.
Interval@(f[x] /. Solve[{f'[x] == 0, 0 <= x <= 2 Pi}, x, Reals] //
FullSimplify // Union)
Interval[{Log[3/2], Log[5/2]}]
Alternatively, with version 10
FunctionRange[f[x], x, y] // FullSimplify
Log[3/2] <= y <= Log[5/2]
Interval@Cases[%, _?NumericQ]
Interval[{Log[3/2], Log[5/2]}]
answered Jan 14, 2015 at 19:31
-
$\begingroup$ @ Bob Hanlon : Having noticed "Since the function is periodic, the limit interval is just the minimum and maximum of the function", you found the minimum and the maximum. This is true only for continuous functions. Nevertheless, I find it smart. However, that way is found by hand and only realized with Mathematica. Could that be called a workaround? $\endgroup$ Commented Jan 14, 2015 at 20:17
-
$\begingroup$ @ Bob Hanlon: One of the votes up is mine. $\endgroup$ Commented Jan 14, 2015 at 21:27
Limit[Sin[x]*Cos[x], x -> Infinity]is a simple example of the bug. $\endgroup$Limitdoes not in general find the tightest possible interval for functions that oscillate. $\endgroup$